Range ( start, stop, step )

Returns a list of numbers given the parameters

Be the first to rate this function Log in to vote

Paul - Show more from this author
Peak 14 LLC
http://www.peak14.solutions

Sample input:

Range ( 1 ; 5; "" )

Sample output:

1
2
3
4
5

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
 *  CUSTOM FUNCTION
 *    Range ( start, stop, step )
 *
 *  DESCRIPTION
 *    Returns a list of numbers given the parameters
 *
 *  PARAMS
 *    start (optional): The number to start the range at. Default is 0.
 *    stop: The number to stop the range at
 *    step (optional): What to increment by. Default is 1 or -1.
 *
 *  RETURNS
 *    A list of numbers
 *
 *  DEPENDENCIES
 *    --None--
 *
 *  CHANGELOG
 *    2022-09-12: Paul McCudden (paul@peak14.solutions): Created
*/

While (
    [
        ~start = GetAsNumber ( start );
        ~stop = GetAsNumber ( stop );
        ~step = GetAsNumber ( step );

        ~start = Case (
            IsEmpty ( ~start ); 0;
            ~start
        );
        ~step = Case (
            not IsEmpty ( ~step ); ~step;
            ~start < ~stop; 1;
            ~start > ~stop; -1
        );
        ~list = "";
        ~currentNumber = ~start;

        ~noLoop = Case (
            ~step = 0; True;
            ~start = ~stop; True;
            ~start < ~stop and ~step < 0; True;
            ~start > ~stop and ~step > 0; True;
            False
        )
    ];

    Case (
        ~noLoop; False;
        ~start < ~stop; ~currentNumber <= ~stop;
        ~start > ~stop; ~currentNumber >= ~stop;
    );

    [
        ~list = List ( ~list; ~currentNumber );
        ~currentNumber = ~currentNumber + ~step
    ];

    Case (
        ~step = 0; Evaluate ( "Factorial ( -1 )" ); // Simulate an out of range error - will never reach stop
        ~start < ~stop and ~step < 0; Evaluate ( "Factorial ( -1 )" ); // Simulate an out of range error - will never reach stop
        ~start > ~stop and ~step > 0; Evaluate ( "Factorial ( -1 )" ); // Simulate an out of range error - will never reach stop
        ~start = ~stop; ~start;
        ~list
    )

)

Returns a list of numbers starting at "start" and stopping at "stop" incrementing by "step".

If stop will never be reached or if step is 0, an out or range error will be simulated.

Both "start" and "step" are optional. Start's default value is 0 and step's default value is either 1 or -1 depending on if start is greater or less than stop.

This is based off the python range() function.
https://www.w3schools.com/python/ref_func_range.asp

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Range ( start, stop, step )

Comments

Support this website.

Support this website.