@JsonFindValue ( json ; value )

Returns a list of paths to each element that contains the specified value.

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonFindValue ("{\"t\":true,\"f\":false}" ; True )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonFindValue ( json ; value )
*
* Returns a list of paths to each element that contains the specified value.
* This CF does not distinguish "" from null and true/false from 1/0.
* If you are searching for a nested JSON object, apply the JSONGetElement()
* function on the value to sort its elements alphabetically.
*
* Usage example:
*
	Let (
		json = JSONSetElement ( "" ;
			[ "s"   ; "1"   ; JSONString ] ; 
			[ "n"   ; 1     ; JSONNumber ] ;
			[ "b.t" ; True  ; JSONBoolean ] ;
			[ "b.f" ; False ; JSONBoolean ]
		) ;
		List (
			@JsonFindValue ( json ; 1 ) ;
			"--" ;
			@JsonFindValue ( json ; "{\"t\":true,\"f\":false}" ) ;
			"--" ;
			@JsonFindValue ( json ; JSONGetElement ( "{\"t\":true,\"f\":false}" ; "" ) ) ;
		)
	)
*
* Result:
*
	.b.t
	.n
	.s
	--
	--
	.b
*
* Created 2022-09-26 by Alex Zueiv
* https://www.briandunning.com/cf/2617
**/


While ( [
	json = JSONGetElement ( json ; "" ) ;
	json = If ( Left ( json ; 1 ) = "?" ; "{}" ; json ) ;
	format = If ( Left ( json ; 1 ) = "[" ; "[]" ; "." ) ;
	names = JSONListKeys ( json ; "" ) ;
	i = ValueCount ( names ) ;
	result = ""
] ; i ; [
	name = GetValue ( names ; i ) ;
	key = If ( PatternCount ( name ; "." ) ; "['" & name & "']" ; name ) ;
	element = JSONGetElement ( json ; key ) ;
	path = Replace ( format ; 2 ; 0 ; key ) ;
	children = @JsonFindValue ( element ; value ) ;
	result = List (
		If ( element = value ; path ) ;
		If ( children ≠ "" ; path & Substitute ( children ; ¶ ; ¶ & path ) ) ;
		result
	) ;
	i = i - 1
] ;
	result
)

Returns a list of paths to each element that contains the specified value.

This CF does not distinguish "" from null and true/false from 1/0.

If you are searching for a nested JSON object, apply the JSONGetElement() function on the value to sort its elements alphabetically.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonFindValue ( json ; value )

Comments

Support this website.

Support this website.