ParseUrl ( _url )

Parse the URL and return the result as JSON.

Be the first to rate this function Log in to vote

Teruhiro Komaki - Show more from this author
frudens Inc.
https://frudens.jp

Sample input:

ParseUrl ( "https://username:password@bucket-demo.s3.us-east-1.amazonaws.com:80/path/to/file.txt?list-type=2&prefix=s3Prefix/a/b/#fragment" )

Sample output:

{
"fileName" : "file.txt",
"fragment" : "fragment",
"host" : "bucket-demo.s3.us-east-1.amazonaws.com",
"password" : "password",
"path" : "/path/to/file.txt",
"port" : "80",
"query" : "list-type=2&prefix=s3Prefix/a/b/",
"scheme" : "https",
"urlIsEmpty" : true,
"userName" : "username"
}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ---------------------------------------------------------------------------
ParseUrl ( _url )

Description:
Parse the URL and return the result as JSON.

Note:
- If urlIsEmpty is 'false', the URL may have failed to parse.
- Please let me know if there is anything I have overlooked.
- For the structure of the URL, I referred to the URL below.
   https://en.wikipedia.org/wiki/URL

Example:
ParseUrl ( "https://username:password@bucketname.s3.ap-northeast-1.amazonaws.com:80/dir1/file.txt?q1=v1&q2=v2#fragment" )
-> {"fileName":"file.txt","fragment":"fragment","host":"bucketname.s3.ap-northeast-1.amazonaws.com","password":"password","path":"/dir1/file.txt","port":"80","query":"q1=v1&q2=v2","scheme":"https","urlIsEmpty":true,"userName":"username"}

ParseUrl ( "https://en.wikipedia.org/wiki/URL" )
-> {"fileName":"","fragment":"","host":"en.wikipedia.org","password":"","path":"/wiki/URL","port":"","query":"","scheme":"https","urlIsEmpty":true,"userName":""}

ParseUrl ( "https://username:password@bucket-demo.s3.us-east-1.amazonaws.com:80/path/to/file.txt?list-type=2&prefix=s3Prefix/a/b/#fragment" )
-> {"fileName":"file.txt","fragment":"fragment","host":"bucket-demo.s3.us-east-1.amazonaws.com","password":"password","path":"/path/to/file.txt","port":"80","query":"list-type=2&prefix=s3Prefix/a/b/","scheme":"https","urlIsEmpty":true,"userName":"username"}

History:
2022-11-24, Teruhiro Komaki <komaki@frudens.jp>
create.
2023-02-24, Teruhiro Komaki <komaki@frudens.jp>
It was fixed because it did not consider the case where "/" was included in the query.
--------------------------------------------------------------------------- */

Let ( [
  // _url = "https://username:password@bucket-demo.s3.us-east-1.amazonaws.com:80/path/to/file.txt?list-type=2&prefix=s3Prefix/a/b/#fragment" ;
  ~url = _url ;
  ~urlLength = Length ( ~url ) ;

  // scheme
  ~scheme = GetValue ( Substitute ( ~url ; "://" ; "¶" ) ; 1 ) ;
  ~schemeLength = Length ( ~scheme & "://" ) ;
  ~url = Middle ( ~url ; ( ~schemeLength + 1 ) ; ~urlLength ) ;

  //userInfo
  ~userinfo = If ( PatternCount ( ~url ; "@" ) ; GetValue ( Substitute ( ~url ; "@" ; "¶" ) ; 1 ) ) ; // username:password@
  ~userinfoLength = Length ( ~userinfo & "@" ) ;
  ~userinfoList = Substitute ( ~userinfo ; ":" ; "¶" ) ;
  ~userName = GetValue ( ~userinfoList ; 1 ) ;
  ~password = GetValue ( ~userinfoList ; 2 ) ;
  ~url = If ( not IsEmpty ( ~userinfo ) ; Middle ( ~url ; ( ~userinfoLength + 1 ) ; ~urlLength ) ; ~url ) ;

  // host
  ~host = GetValue ( Substitute ( ~url ; [ ":" ; "¶" ] ; [ "/" ; "¶" ] ; [ "?" ; "¶" ] ; [ "#" ; "¶" ] ) ; 1 ) ;
  ~hostLength = Length ( ~host ) ;
  ~url = Middle ( ~url ; ( ~hostLength + 1 ) ; ~urlLength ) ;

  // port
  ~port = GetAsNumber ( GetValue ( Substitute ( ~url ; [ "/" ; "¶" ] ; [ "?" ; "¶" ] ; [ "#" ; "¶" ] ) ; 1 ) ) ;
  ~portLength = Length ( ":" & ~port ) ;
  ~url = If ( not IsEmpty ( ~port ) ; Middle ( ~url ; ( ~portLength + 1 ) ; ~urlLength ) ; ~url ) ;

  // path
  ~path = GetValue ( Substitute ( ~url ; [ "?" ; "¶" ] ; [ "#" ; "¶" ] ) ; 1 ) ;
  ~pathLength = Length ( ~path ) ;
  ~url = If ( not IsEmpty ( ~path ) ; Middle ( ~url ; ( ~pathLength + 1 ) ; ~urlLength ) ; ~url ) ;

  // file
  ~pathList = Substitute ( ~path ; "/" ; "¶" ) ;
  ~pathListLast = GetValue ( ~pathList ; ValueCount ( ~pathList ) ) ;
  ~fileName = If ( GetAsBoolean ( PatternCount ( ~pathListLast ; "." ) ) ; ~pathListLast ; "" ) ;

  // query
  ~isQuery = GetAsBoolean ( Left ( ~url ; 1 ) = "?" ) ;
  ~query = GetValue ( Substitute ( ~url ; [ "?" ; "" ] ; [ "#" ; "¶" ] ) ; 1 ) ;
  ~queryLength = Length ( "?" & ~query ) ;
  ~url = If ( ~isQuery ; Middle ( ~url ; ( ~queryLength + 1 ) ; ~urlLength ) ; ~url ) ; 

  // fragment
  ~fragment = GetValue ( Substitute ( ~url ; [ "#" ; "¶" ] ) ; 2 ) ;
  ~fragmentLength = Length ( "#" & ~fragment ) ;
  ~url = If ( not IsEmpty ( ~fragment ) ; Middle ( ~url ; ( ~fragmentLength + 1 ) ; ~urlLength ) ; ~url ) ;

  // check
  ~urlIsEmpty = If ( IsEmpty ( ~url ) ; True ; False )

] ;

JSONSetElement ( "" ;
  [ "scheme" ; ~scheme ; JSONString ] ;
  [ "userName" ; ~userName ; JSONString ] ;
  [ "password" ; ~password ; JSONString ] ;
  [ "host" ; ~host ; JSONString ] ;
  [ "port" ; ~port ; JSONString ] ;
  [ "path" ; ~path ; JSONString ] ;
  [ "fileName" ; ~fileName ; JSONString ] ;
  [ "fragment" ; ~fragment ; JSONString ] ;
  [ "query" ; ~query ; JSONString ] ;
  [ "urlIsEmpty" ; ~urlIsEmpty ; JSONBoolean ]
)

) /*Let*/

Parse the URL and return the result as JSON.

- If urlIsEmpty is 'false', the URL may have failed to parse.
- Please let me know if there is anything I have overlooked.
- For the structure of the URL, I referred to the URL below.
https://en.wikipedia.org/wiki/URL

Comments

		JoÃ£o Coutinho Nov 24, 2022
Nice!!

		Teruhiro Komaki, frudens Inc. Feb 24, 2023
It was fixed because it did not consider the case where "/" was included in the query.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ParseUrl ( _url )

Comments

Support this website.

Support this website.