get_text_part_between_opener_and_closer ( text ; opener ; opener_occurrence ; closer ; error_indicator )

Extracts the part of text between opener ( that is opener's opener_occurrence ) and the first closer after closer.

Be the first to rate this function Log in to vote

Frank van der Most - Show more from this author
Rubber Boots Data
https://rubberbootsdata.com

Sample input:

get_text_part_between_opener_and_closer ( "abcdabefghijk" ; "ab" ; 2 ; "ij" ; "??" )

Sample output:

efgh

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// Definition of custom function get_text_part_between_opener_and_closer

// From text, gets the part between the opener_occurrence occurrence of opener and the first of occurrence of closer after opener

// If IsEmpty ( closer ) then the result is everything after the opener_occurrence occurrence of opener

// If IsEmpty ( opener ) then the result is everything before the closer

// example : get_text_part_between_opener_and_closer ( "abcdabefghijk" ; "ab" ; 2 ; "ij" ; "??" ) = 'efgh'

// example : get_text_part_between_opener_and_closer ( "abcdabefghijk" ; "" ; 1 ; "ij" ; "??" ) = 'abcdabefgh'

// example : get_text_part_between_opener_and_closer ( "abcdabefghijk" ; "ab" ; 2 ; "" ; "??" ) = 'efghijk'



// Note that even though the result is presented case sensitive, the searches for opener and closer are NOT case sensitive because FMP's position function is not case sensitive

// https://frankvandermost.com
// https://rubberbootsdata.com


// FIRST VERSION : 27 Jan. 2023

// REVISION : 9 Feb. 2023
// Added possibility of empty opener or closer

Let ( [

	/* Start of test parameters

		text = "abcdabefghijk" ;

		opener = "ab" ;

		opener_occurrence = 2 ;

		closer = "" ;

		error_indicator = "??" ;

	End of test parameters */

		position_of_opener = Position ( text ; opener ; 1 ; opener_occurrence ) ;

		length_opener = Length ( opener ) ;

		position_of_closer = Position ( text ; closer ; position_of_opener + length_opener ; 1 )

	] ;

		Case (

			IsEmpty ( opener ) and position_of_closer ;

				Left ( text ; position_of_closer - 1 ) ;

			IsEmpty ( closer ) and position_of_opener ;

				Right ( text ; length ( text ) - position_of_opener - length_opener + 1  ) ;

			position_of_closer > position_of_opener + length_opener - 1 and position_of_opener ;

				Middle ( text ; position_of_opener + length_opener ; position_of_closer - position_of_opener - length_opener ) ;

			error_indicator

		)

)

From text, gets the part between the opener_occurrence occurrence of opener and the first of occurrence of closer after opener
If IsEmpty ( closer ) then the result is everything after the opener_occurrence occurrence of opener
If IsEmpty ( opener ) then the result is everything before the closer

Since the text parameter can contain any text, it is hard to come up with a universal error indicator. Hence the error_indicator parameter.

Perhaps similar functions already exist in the database. I could only find ExtractPortion, which seems too simple.

I wrote this function to retrieve text from a URL but there are of course plenty of applications.

I have tested the function somewhat, but perhaps there are situations that would slip past the safety test.

My only regret with this function is that FM's position function is not case sensitive. Fortunately, there are solutions for that in this database.

If you release the comment with test parameters, you can run the function also in the data viewer or use it directly in a calculation.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

get_text_part_between_opener_and_closer ( text ; opener ; opener_occurrence ; closer ; error_indicator )

Comments

Support this website.

Support this website.