XMLPrettyPrint ( XML ; whiteSpace ; indentLevel ; ContentLine )

This takes a block of XML and formats it with white space to make it readable.

Be the first to rate this function Log in to vote

Mark Geerdes - Show more from this author
Technology By Design
https://www.tbdmn.com

Sample input:

XMLPrettyPrint ( "ToveJaniReminderDon't forget me this weekend!" ; " " ; "" ; "" )

Sample output:

Tove
Jani
Reminder
Don't forget me this weekend!

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * XMLPrettyPrint ( XML ; whiteSpace ; [indentLevel ; ContentLine])
 *
 * PURPOSE:
 *	Formats XML into human readable form by adding indentation
 *
 * RETURNS:
 *	XML indented
 *
 * PARAMETERS:
 *	XML = the XML to indent
 *	whiteSpace = the spacing to use for the indents
 *	indentLevel = recursive, so we need to keep track of how many indents we have - optional, used in function
 *	ContentLine = 1 if the current line is a content line that includes a close tag (ie. <tag>blah</tag> ) - optional, used in function in default Case below
 *
 * DEPENDENCIES:
 *	XMLIndent Custom Function
 *
 * HISTORY:
 *	2016/03/24 Mark Geerdes Created
 *
 * =====================================
 */

// XMLIndent ( XML ; whiteSpace ; indentLevel )
// XMLPrettyPrint ( XML ; whiteSpace ; indentLevel ; ContentLine )

Let ( [ 
	tagEnd = Position ( XML ; ">" ; 1 ; 1 ) ;
	previousChar = Middle ( XML ; tagEnd -1 ; 1 ) ;
	nextTwoChar = Middle ( XML ; tagEnd +1 ; 2 ) ;
	nextChar = Middle ( XML ; tagEnd +1 ; 1 ) ;
	totalLength = Length ( XML )
]; 
	Case ( 
		nextTwoChar = "</" ; 
		Left ( XML ; tagEnd ) & "¶" &
			If ( indentLevel <2 ; 
				Right ( XML ; totalLength - tagEnd ) ; 
				XMLPrettyPrint ( XMLIndent ( Right ( XML ; totalLength - tagEnd ) ; whiteSpace ; indentLevel -1 ) ; whiteSpace ; indentLevel -1 ; 1 ) 
			) ; 
		previousChar = "/" or (ContentLine and nextChar = "<") ; 
		Left ( XML ; tagEnd ) & "¶" &
			XMLPrettyPrint ( XMLIndent ( Right ( XML ; totalLength - tagEnd ) ; whiteSpace ; indentLevel ) ; whiteSpace ; indentLevel ; "");
		nextChar = "<" ;
		Left ( XML ; tagEnd ) & "¶" & 
			XMLPrettyPrint ( XMLIndent ( Right ( XML ; totalLength - tagEnd ) ; whiteSpace ; indentLevel +1 ) ; whiteSpace ; indentLevel +1 ; "" ) ;
		Left ( XML ; tagEnd ) & XMLPrettyPrint (  Right ( XML ; totalLength - tagEnd ) ; whiteSpace ; indentLevel ; 1 )
	)

)

This takes a block of XML and formats it with white space to make it readable.
Uses the XMLIndent custom function

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

XMLPrettyPrint ( XML ; whiteSpace ; indentLevel ; ContentLine )

Comments

Support this website.

Support this website.