ValueIndex ( valueList , valueString , matchCase , occurrence )

Returns the index/position of the matching valueString in the valueList. Returns 0 if not found.

Be the first to rate this function Log in to vote

Lewis Lorenz - Show more from this author
Lorenz Companies
http://www.LorenzCom.com

Sample input:

ValueIndex ("Alpha¶Bravo¶Charlie¶Echo", "charlie", False, 1)

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

While ( [ 
	~list = ¶ & valueList & ¶; 
	~value =  ¶ & valueString & ¶;
	~occ = occurrence;
	~pos = 0;
	~start = If ( ~occ < 0; Length ( ~list ); 1 );
	~ismatch = False;
	~index = 0
	]; 

		GetAsBoolean ( ~occ );

	[
	//Continue searching for one at a time until pos is 0 then change occ to 0 to exit while.
	~pos = If ( ~occ = 0; 0; Position( ~list; ~value; ~start;  If ( ~occ < 0; -1; 1 ) ) );
	//Get index of found valueString in valueList.
	~index = If ( ~pos; ValueCount ( Left ( ~list; ~pos ) ); 0 );
	//Match testing.
	~ismatch = Exact ( GetValue ( valueList; ~index ); valueString );
	//Adjust where to begin looking for next ~value in ~list.
	~start = ~pos + If ( ~occ < 0; -1; 1 );
	//Adjust occurrence toward 0. If pos = 0 then set to 0. If matchCase then adjust only if is matched, else adjust all. 
	~occ = Case ( ~pos = 0; 0; GetAsBoolean ( matchCase ); If ( ~ismatch; ~occ + If ( ~occ > 0; -1; 1 ); ~occ); ~occ + If ( ~occ > 0; -1; 1 ) )
	];

	~index

)

/* 
ValueIndex ( valueList , valueString , matchCase , occurrence )

by Lewis C. Lorenz.

5/14/2023: Updated. 

Returns the index/position of the matching valueString in the valueList. Returns 0 if not found.
Require case-sensitive searching by passing a boolean through matchCase. 
Search for specific valueString occurrence. Also, a negative occurrence number causes backward search from the end of the valueList.

NOTICE: Requires FileMaker 18+

Examples: 
ValueIndex ("Alpha¶Bravo¶Charlie¶Echo", "charlie", False, 1) = 3
ValueIndex ("Alpha¶Bravo¶Charlie¶Echo", "charlie", True, 1) = 0
ValueIndex ("Danial¶Daniel¶Bill¶daniel¶Frank¶daniel¶Ed", "daniel", True, -2) = 4
*/

ValueIndex ( valueList , valueString , matchCase , occurrence )

Returns the index/position of the matching valueString in the valueList. Returns 0 if not found.
Require case-sensitive searching by passing a boolean through matchCase.
Search for specific valueString occurrence. Also, a negative occurrence number causes backward search from the end of the valueList.

NOTICE: Requires FileMaker 18+

Comments

		Michael Horak, *COMMENT Visual Realisation May 19, 2023
Compare: https://www.briandunning.com/cf/2607

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValueIndex ( valueList , valueString , matchCase , occurrence )

Comments

Support this website.

Support this website.