DateFormatStrftime ( someTimeStamp ; formatString )

Format a date/timestamp using the format defined by the POSIX/UNIX 'strftime'

Be the first to rate this function Log in to vote

Dan Shockley - Show more from this author

Sample input:

DateFormatStrftime ( "3/9/2023 4:57:00 PM" ; "%-m/%-d/%y" )

Sample output:

"3/9/23"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// DateFormatStrftime ( someTimeStamp ; formatString )
// version 2023-10-06, Daniel A. Shockley

/*
	Formats a timestamp using the (slightly modified) format defined by the POSIX command 'strftime' 

EXAMPLES:
 	(if the current timestamp is Wednesday, March 9, 2011 at 1:22:26 PM:

	DateFormatStrftime ( Get ( CurrentTimestamp ) ; "%Y-%m-%d--%H-%M-%S" )
	>>	Result: 2011-03-09--13-22-26

	DateFormatStrftime ( Get ( CurrentTimestamp ) ; "%m/%d/%Y %H:%M:%S" )
	>>	Result: 03/09/2011 13:22:26

	DateFormatStrftime ( Get ( CurrentTimestamp ) ; "%-m/%-d/%y" )
	>>	Result: 3/9/11


	DateFormatStrftime ( Get ( CurrentTimestamp ) ; "DATE: %m/%d/%y%nTIME: %H:%M:%S" )
	>>	Result: (see lines below, since the format string specified a line separator)
			DATE: 03/09/11
			TIME: 13:22:26

	DateFormatStrftime ( Get ( CurrentTimestamp ) ; "%A, %B %e, %Y" )
	>>	Result: Wednesday, March  9, 2011

HISTORY ( recent at top ): 
	2023-10-06 ( danshockley ): Fix so that locale's time and date work properly using FileMaker's functions to determine, rather than hard-coding for U.S. format. Updated documentation to mention locale where supported (but not yet AM/PM, for example). 
	2023-01-05 ( danshockley ): Updated documentation. 
	2020-11-23 ( danshockley ): Added special "File_Friendly_NOW" to get a date-time slug without seconds that is easier for non-tech people to read. Added padding-off for e,j,k,l flags. Added %-p (NON-standard!) to get lower-case am/pm. 
	2020-08-03 ( danshockley ): Added the special "File…NOW" options to make it EASY to get a NOW date-time slug for a file path (no slashes/colons).
	2019-12-12 ( danshockley ): Added the %-* option for relevant symbols (*) to turn off zero-padding (symbols are: CdHIjMmSUy). FIX: %I should be zero-padded. FIX: %C should be a zero-padded decimal number. Properly show %g and %G as not being implemented. FIX: %u is Monday=1. Improved documentation. 
	2019-10-29 ( danshockley ): Modernized code format. Added "Help" param. Properly support a simple date (time component defaults to midnight). 
	2011-05-23 ( danshockley ): Added comments. 
	2011-02-08 ( danshockley ): First created. 
	
*/


If ( someTimeStamp = "Help"
	/* DISPLAY HELP INFO: */
	; List ( 
		  "DateFormatStrftime ( someTimeStamp ; formatString )"
		; "Specify some date/timestamp, then also specify a format string, where the following symbols are replaced by part(s) or your specified date/timestamp: "
		; " "
		; "--- SPECIAL COMMANDS/OPTIONS (use instead of someTimestamp param, formatString will be ignored): ---"
		; "   Help  >  returns this documentation."
		; "   File_NOW  >  Current Date/Time as YYYY-MM-DD-HHMMSS, equivalent to '%Y-%m-%d-%H%M%S'. "
		; "   File_AsNum_NOW  >  Current Date/Time as YYYYMMDDHHMMSS, equivalent to '%Y%m%d%H%M%S'. "
		; "   File_AsDateLine_NOW  >  Current Date/Time as 'MonthName DayNum, YYYY, HHMMSS', equivalent to '%b %-d, %Y, %H%M%S'.  (e.g. 'November 23, 2020, 174959')"
		; "   File_Friendly_NOW  >  Current Date/Time as 'YYYY-MM-DD HHMM[AM/PM]', equivalent to '%Y-%m-%d %-l%M%-p'.  (e.g. '2020-11-23 549pm')"
		; " "
		; "--- FORMAT STRING SYMBOLS: ---"
		; "%a  >  Replaced by the abbreviated weekday name." 
		; "%A  >  Replaced by the locale's full weekday name." 
		; "%b  >  Replaced by the locale's abbreviated month name." 
		; "%B  >  Replaced by the locale's full month name." 
		; "%c  >  Replaced by locale's representation of time and date." 
		; "%C  >  Replaced by the century number (the year divided by 100 and truncated to an integer) as a decimal number [00-99]." 
		; "%D  >  Equivalent to '%m/%d/%y'." 
		; "%d  >  Replaced by the day of the month as a decimal number [01,31]." 
		; "%e  >  Replaced by the day of the month as a decimal number [1,31]; a single digit is preceded by a space." 
		; "%E* %O*  >  NOT IMPLEMENTED. " 
		; "%F  >  Equivalent to '%Y-%m-%d'." 
		; "%g  >  NOT IMPLEMENTED." 
		; "%G  >  NOT IMPLEMENTED." 
		; "%h  >  Equivalent to %b." 
		; "%H  >  Replaced by the hour (24-hour clock) as a decimal number (00-23)." 
		; "%I  >  Replaced by the hour (12-hour clock) as a decimal number (01-12)." 
		; "%j  >  Replaced by the day of the year as a decimal number (001-366)." 
		; "%k  >  Replaced by the hour (24-hour clock) as a decimal number (0-23); single digits are preceded by a space." 
		; "%l  >  Replaced by the hour (12-hour clock) as a decimal number (1-12); single digits are preceded by a space." 
		; "%m  >  Replaced by the month as a decimal number (01-12)." 
		; "%M  >  Replaced by the minute as a decimal number (00-59)." 
		; "%n  >  Replaced by a newline." 
		; "%O*  >  NOT IMPLEMENTED." 
		; "%p  >  Replaced by either 'ante meridiem' (a.m.)  or 'post meridiem' (p.m.)  as appropriate." 
		; "%r  >  Replaced by the time in a.m. and p.m. notation;  in the POSIX locale this shall be equivalent to %I:%M:%S %p" 
		; "%R  >  Replaced by the time in 24-hour notation ( %H:%M ). " 
		; "%s  >  Replaced by the number of seconds since the Epoch, UTC (see mktime(3))." 
		; "%S  >  Replaced by the second as a decimal number (00-60)." 
		; "%t  >  Replaced by a TAB character." 
		; "%T  >  Replaced by the time ( %H:%M:%S )." 
		; "%u  >  Replaced by the weekday (Monday as the first day of the week) as a decimal number (1-7)." 
		; "%U  >  Replaced by the week number of the year (Sunday as the first day of the week) as a decimal number (00-53)." 
		; "%v  >  Equivalent to '%e-%b-%Y'." 
		; "%V  >  NOT IMPLEMENTED." 
		; "%w  >  Replaced by the weekday (Sunday as the first day of the week) as a decimal number (0-6)." 
		; "%W  >  NOT IMPLEMENTED." 
		; "%x  >  Replaced by locale's representation of the date." 
		; "%X  >  Replaced by locale's representation of the time." 
		; "%y  >  Replaced by the year without century as a decimal number (00-99)." 
		; "%Y  >  Replaced by the year with century as a decimal number." 
		; "%z  >  NOT IMPLEMENTED." 
		; "%Z  >  NOT IMPLEMENTED." 
		; "%+  >  Replaced by the date and time (the format is similar to that produced by date(1))." 
		; "%-*  >  Use instead of merely '%' with a symbol (*) to turn off padding for that symbol's output. (e.g. Use '%-d' to get the day of month as 1-31 instead of 01-31)" 
		; "%_*  >  NOT IMPLEMENTED." 
		; "%0*  >  NOT IMPLEMENTED." 
		; "%%  >  Replaced by '%' (percentage sign, in case it is desired in the output)." 
		)

	/* RUN ACTUAL FORMATTING: */
	; Let ( [
			/* build various useful pieces, with abbreviated function names: */
			
			/* In case the incoming param is just a date or time, ensure it is a timestamp. 
				Note: this will convert a simple date into a timestamp at MIDNIGHT of that date.
				*/

			  sTS = 
				If ( PatternCount ( someTimeStamp ; "NOW" ) > 0
					; Get ( CurrentHostTimestamp )
					; GetAsTimestamp ( someTimeStamp )
					)

			; formatString = 
				Case ( 
					someTimeStamp = "File_NOW" 
					; "%Y-%m-%d-%H%M%S"
					; 
					someTimeStamp = "File_AsNum_NOW" 
					; "%Y%m%d%H%M%S"
					; 
					someTimeStamp = "File_AsDateLine_NOW" 
					; "%b %-d, %Y, %H%M%S"
					; 
					someTimeStamp = "File_Friendly_NOW" 
					; "%Y-%m-%d %-I%M%-p" 
					; 
					/* otherwise, just use what was specified: */
					formatString
					)

			; dN = Day ( sTS )
			; dN2 = Right ( "0" & dN ; 2 )
			; dN_space = Right ( " " & dN ; 2 )
			; dName = DayName ( sTS )
			; dName3 = Left ( dName ; 3 )

			; dOfWkN = DayOfWeek ( sTS )    /* FM's DayOfWeek gives Sunday as 1, Saturday as 7 */
			; dOfWk_Mon_is_1 = If ( dOfWkN = 1 ; 7 ; dOfWkN - 1 )

			; moN = Month ( sTS )
			; moN2 = Right ( "0" & moN ; 2 )
			; moName = MonthName ( sTS )
			; moName3 = Left ( moName ; 3 )

			; yN = Year ( sTS )
			; yN2 = Right ( "0" & Right ( yN ; 2 ) ; 2 )
			; century = Div ( yN ; 100 )
			; century_padded = Right ( "0" & century ; 2 )

			; hN = Hour ( sTS )
			; hN2 = Right ( "0" & hN ; 2 )

			; hN_space = Right ( " " & hN ; 2 )

			; hN_clock = If ( hN > 12 ; hN - 12 ; hN )
			; hN_clock2 = Right ( "0" & hN_clock ; 2 )

			; hN_clock_space = Right ( " " & hN_clock ; 2 )

			; amPm = If( hN >= 12; "PM" ; "AM" )

			; minN = Minute ( sTS )
			; minN2 = Right ( "0" & minN ; 2 )

			; sN = Seconds ( sTS )
			; sN2 = Right ( "0" & sN ; 2 )

			; wN = WeekOfYear ( sTS )
			; wN2 = Right ( "0" & wN ; 2 )

			; locRepDate = GetAsText ( Date ( moN ; dN ; yN ) )
			; locRepTime = GetAsText ( Time ( hN ; minN ; sN ) )
	]; 

	/* Swap in the formatted pieces, replacing the format symbols: */
	Substitute ( 
		  formatString
		; [ "%a" ; dName3 ] 
		; [ "%A" ; dName ] 
		; [ "%b" ; moName3 ] 
		; [ "%B" ; moName ] 
		; [ "%c" ; locRepTime & ", " & locRepDate ] 
		; [ "%-C" ; century ] 
		; [ "%C" ; century_padded ] 
		; [ "%-d" ; dN ] 
		; [ "%d" ; dN2 ] 
		; [ "%D" ; moN2 & "/" & dN2 & "/" & yN2 ] 
		; [ "%-e" ; dN ] 
		; [ "%e" ; dN_space ] 
		//; [ "%E" ; "POSIX locale extensions" ]    /* NOT IMPLEMENTED */
		; [ "%F" ; yN & "-" & moN2 & "-" & dN2 ] 
		//; [ "%g" ; "Same as %G, but without century." ]    /* NOT IMPLEMENTED */
		//; [ "%G" ; "Year as decimal - year with greater part of week." ]    /* NOT IMPLEMENTED */
		; [ "%-H" ; hN ] 
		; [ "%H" ; hN2 ] 
		; [ "%h" ; Left( moName; 3 ) ] 
		; [ "%-I" ; hN_clock ] 
		; [ "%I" ; hN_clock2 ] 
		; [ "%-j" ; DayOfYear ( sTS ) ] 
		; [ "%j" ; Right( "00" & DayOfYear ( sTS ); 3 ) ] 
		; [ "%-k" ; hN ] 
		; [ "%k" ; hN_space ] 
		; [ "%-l" ; hN_clock ] 
		; [ "%l" ; hN_clock_space ] 
		; [ "%-m" ; moN ] 
		; [ "%m" ; moN2 ] 
		; [ "%-M" ; minN ] 
		; [ "%M" ; minN2 ] 
		; [ "%n" ; Char ( 13 ) ] 
		//; [ "%O" ; "Same as %E" ]    /* NOT IMPLEMENTED */
		; [ "%-p" ; Lower ( amPm ) ] 
		; [ "%p" ; amPm ] 
		; [ "%r" ; hN_clock & ":" & minN2 & ":" & sN2 & " " & amPm ] 
		; [ "%R" ; hN2 & ":" & minN2 ] 
		; [ "%s" ; GetAsNumber ( Get ( CurrentTimestamp ) - Timestamp ( Date ( 12 ; 31 ; 1969 ) ; Time ( 19 ; 0 ; 0 ) ) ) ] 
		; [ "%-S" ; sN ] 
		; [ "%S" ; sN2 ] 
		; [ "%t" ; Char ( 9 ) ] 
		; [ "%T" ; hN2 & ":" & minN2 & ":" & sN2 ] 
		; [ "%-U" ; wN ] 
		; [ "%U" ; wN2 ] 
		; [ "%u" ; dOfWk_Mon_is_1  ]
		//; [ "%V" ; "Week number of year, but Jan 1 week might be 52"  ]    /* NOT IMPLEMENTED */
		//; [ "%S" ; sN2  ]    /* NOT IMPLEMENTED */
		; [ "%v" ; dN_space & "-" & moName3 & "-" & yN ] 
		//; [ "%W" ; "Week number of year, 00-53"  ]    /* NOT IMPLEMENTED */
		; [ "%w" ; dOfWkN - 1 ] 
		; [ "%x" ; locRepDate ] 
		; [ "%X" ; locRepTime ] 
		; [ "%Y" ; yN ] 
		; [ "%-y" ; yN ] 
		; [ "%y" ; yN2 ] 
		//; [ "%Z" ; "time zone name"  ]     /* NOT IMPLEMENTED */
		//; [ "%Z" ; "time zone offset from UTC"  ]     /* NOT IMPLEMENTED */
		; [ "%+" ; locRepDate & " " & locRepTime ] 
		; [ "%%" ; "%" ] 
	 	)

	)

)

There are a bunch of useful "format some date/timestamp" functions, but I've used this for a long time. But, it is also possible to just use a long-standing set of formatting codes defined long ago by the 'strftime' POSIX shell command built into UNIX. See https://manpages.org/strftime
Most of its formatting codes are supported - see the function's documentation.

There are a few special uses:
- If you send "Help" for the 1st param, you get usage instructions, which is good when you don't remember a formatting code.
- If you send "NOW" for the 1st param, it uses the CurrentHostTimestamp, along with your format string.
- If you send "File_NOW" for the 1st param, it uses the CurrentHostTimestamp and you can leave the formatString empty. It will format a timestamp that works within a filename on any OS platform (no slashes or colons), in an ISO8601-style format.
- If you send "File_AsNum_NOW" for the 1st param, it uses the CurrentHostTimestamp and you can leave the formatString empty. It will format a timestamp that works within a filename on any OS platform (no slashes or colons), but specifically with no punctuation, just numbers.
- If you send "File_AsDateLine_NOW" for the 1st param, it uses the CurrentHostTimestamp and you can leave the formatString empty. It will format a timestamp as a simple dateline like you'd see in a news article.
- If you send "File_Friendly_NOW" for the 1st param, it uses the CurrentHostTimestamp and you can leave the formatString empty. It will format a timestamp that works within a filename on any OS platform (no slashes or colons), in a human-friendly format.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

DateFormatStrftime ( someTimeStamp ; formatString )

Comments

Support this website.

Support this website.