GetDLScan ( ImportPath ; Repetition ; Output )

Imports and parses scanned AAMVA driver's licence information (in JSON format) so that it can be displayed in a button bar, used in a script, etc. without having to import the data as a FileMaker record.

Be the first to rate this function Log in to vote

Matt C - Show more from this author

Sample input:

GetDLScan("C:\import";1;2)

Sample output:

SURNAME, FIRSTNAME MIDDLE NAME (DOB)
IDNUMBER (JURISDICTION)

AYALA, DONALD PETER (1971-09-02)
G824981603700 FL

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// GetDLScan(ImportPath; Repetiton; Output)
//------------------------------------------------------------------------------------------------------------
// Purpose:	This function is used to parse and output JSON files containing AAMVA drivers licence
//		data that has been stored in a directory.
//
//		The files are iterated in descending order (newest ones are repetition 1, 2, 3)
//
//		This function can be used directly from a button bar to display a value and provide JSON
// 		data for a Script Parameter.
//------------------------------------------------------------------------------------------------------------
// Parameters:	ImportPath - (e.g. C:\JSONData - native OS file path) where JSON files are stored
//		Repetition   - The file that is being parsed from the directory (newest file = 1)
//    		Output        - The format to be output by the function (1 = JSON data, 2 = Label)
//------------------------------------------------------------------------------------------------------------
// Dependencies:	- BaseElements plugin (https://docs.baseelementsplugin.com)
//		- AAMVAJurisdiction function (https://www.briandunning.com/cf/2684)
//------------------------------------------------------------------------------------------------------------
// Author:	Matt Cudmore
//		August 28, 2023
//------------------------------------------------------------------------------------------------------------


Let ( [
	~$filenum = Repetition; 

	~$importpath = ImportPath;

	~$jsondata = BE_FileReadText ( ~$importpath & GetValue ( BE_ValuesSort ( BE_FileListFolder ( ~$importpath); 0 ; 0 ) ; ~$filenum) );
	
	~$jsondatavalid = If ( PatternCount ( ~$jsondata; "IDNumber" ) = 0; False; True)
	];

/* Output 1 - JSON data */
	If ( ~$jsondatavalid =True and Output = 1; ~$jsondata; ""  )&

/* Output 2 - Label information */
	If ( ~$jsondatavalid = True and Output = 2;
		TrimAll(
			JSONGetElement ( ~$jsondata ; "Name.Last" ) &", "&
			JSONGetElement ( ~$jsondata ; "Name.First" )& " " &
			JSONGetElement ( ~$jsondata ; "Name.Middle" )
			& " (" &
			Left(JSONGetElement ( ~$jsondata ; "DateOfBirth" );10) & ")"&
			¶&
			JSONGetElement ( ~$jsondata ; "IdNumber" )& " " & 
			AAMVAJurisdiction ( JSONGetElement ( ~$jsondata ; "IssuerIdentificationNumber" ); 1)
		;0;0)
	; "")
)

Dependencies:
- BaseElements plugin (https://docs.baseelementsplugin.com)
- AAMVAJurisdiction function (https://www.briandunning.com/cf/2684)

This function is designed to be used to import driver's licence data (in JSON format) which has been captured using a card scanner from an AAMVA-compatible driver's licence document.

This function allows you to work with and display the JSON data without the need to import it into a FileMaker record.

For example, using this formula, you can create a button bar with 4 segments. Each segment represents a different repetition value. You can use output option 1 (JSON) as part of a button script parameter, and output option 2 (label) as a calculated button label.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetDLScan ( ImportPath ; Repetition ; Output )

Comments

Support this website.

Support this website.