JSONToQueryParams ( json ; skipNullValues )

Convert json data to a query parameter-style format where each key and each value are url-encoded

Be the first to rate this function Log in to vote

Mislav Kos - Show more from this author
Soliant Consulting
https://www.soliantconsulting.com/

Sample input:

{"abc":"hello world","foo":"bar"}

Sample output:

abc=hello%20world&foo=bar

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// Signature:
// JSONToQueryParams ( json ; skipNullValues )

// Purpose:
// Convert json data to a query parameter-style format where each key and each value are url-encoded.
// Example:  {"abc":"hello world","foo":"bar"}  =>  abc=hello%20world&foo=bar
// An example of where this is useful is when generating a pre-signed S3 url for uploading a file.
// If you want to include tags when the S3 object is created, you'll need to specify a Tagging property whose value needs to use a query parameter-style format.
// In FileMaker, it's simpler to construct a json object, but S3 tagging requires tags to be specified in a query param-style format.

// Parameter:
// json: json data that should be converted to query-parameter format
// skipNullValues: if true, skip keys whose values are null or empty

// Dependencies:
// None

// History:
// 2023-09-22 Mislav Kos <mkos@soliantconsulting.com>: Created custom function.

Let ( 
	keys = JSONListKeys ( json ; "" ) ; 
	If ( 
		Left ( keys ; 3 ) = "? *" ; 
		"?" ; 
		While ( 
		[ 
			limit = ValueCount ( keys ) ; 
			i = 1 ; 
			result = "" 
		] ; 
			i ≤ limit ; 
		[ 
			key = GetValue ( keys ; i ) ; 
			value = JSONGetElement ( json ; key ) ; 
			result = result & If ( 
				not ( IsEmpty ( value ) and skipNullValues ) ; 
				If ( i > 1 ; "&" ) & GetAsURLEncoded ( key ) & "=" & GetAsURLEncoded ( value ) 
			) ; 
			i = i + 1 
		] ; 
			result 
		)
	)
)

Convert json data to a query parameter-style format where each key and each value are url-encoded.

For example: {"abc":"hello world","foo":"bar"} => abc=hello%20world&foo=bar

An example of where this is useful is when generating a pre-signed S3 url for uploading a file. If you want to include tags when the S3 object is created, you'll need to specify a Tagging property whose value needs to use a query parameter-style format.

In FileMaker, it's simpler to construct a json object, but S3 tagging requires tags to be specified in a query param-style format.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSONToQueryParams ( json ; skipNullValues )

Comments

Support this website.

Support this website.