JSONDeleteEmptyElements ( json )

Removes any empty values from a JSON object or array of objects

Be the first to rate this function Log in to vote

Jake Scheele - Show more from this author
Edimate
http://www.edimate.com

Sample input:

JSONFormatElements ( JSONDeleteEmptyElements ( JSONSetElement ( "{}"
;[ " empty" ; "" ; 1 ]
;[ "full" ; "full" ; 1 ]
;[ "object.empty" ; "" ; 1 ]
;[ "object.full" ; "full" ; 1 ]
;[ "arrayofObjects[0]empty" ; "" ; 1 ]
;[ "arrayofObjects[0]full" ; "full" ; 1 ]
;[ "arrayofObjects[1]empty2" ; "" ; 1 ]
;[ "arrayofObjects[1]full2" ; "full" ; 1 ]
;[ "arrayofObjects[1]tester" ; "" ; 1 ]
;[ "array[0]" ; "1" ; 1 ]
;[ "array[1]" ; "2" ; 1 ]
;[ "array[2]" ; "" ; 1 ]
;[ "array[3]" ; "4" ; 1 ]
) ) )

Sample output:

{
"array" : [ 1, 2, "", 4 ],
"arrayofObjects" :
[
{
"full" : "full"
},
{
"full2" : "full"
}
],
"full" : "full",
"object" :
{
"full" : "full"
}
}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// JSONDeleteEmptyElements ( json )
// Author/Date:	Jake Scheele 1/22/24 www.edimate.com
// Purpose:		Removes any empty values from a JSON object or array of objects
// Notes:		Recursive function, calls itself to evaluate nested objects

While ([ ~json = json
	; ~values = If ( JSONGetElementType ( ~json ; "" ) = JSONArray 
				; JSONGetElement ( ~json ; ( JSONListValues ( ~json ; "" ) ) ) 
				; JSONListKeys ( ~json ; "" )
			   )
	; ~counter = 0	
	; ~countValues = ValueCount ( ~values )
	; ~result = ~json
 ]; 
	~counter < ~countValues // condition to run while loop (only runs while condition is true)
 ;[ logic = 1
	; ~counter	= ~counter + 1
	; ~key		= GetValue ( ~values ; ~counter )
	; ~value		= JSONGetElement ( ~json ; ~key )
	; ~isObject	= JSONGetElementType ( ~value ; "" ) = JSONObject
	; ~isArray	= JSONGetElementType ( ~value ; "" ) = JSONArray
	; ~isEmpty	= IsEmpty ( JSONGetElement ( ~json ; ~key ) )
	; ~result	= Case (0;0
					; ~isObject	; JSONSetElement    ( ~result ; ~key ; JSONDeleteEmptyElements ( ~value ) ; JSONGetElementType ( ~value ; "" ) ) 
					; ~isArray	; JSONSetElement    ( ~result ; ~key ; 
						While ([ initialVariables = 1
							; ~values = JSONListValues ( JSONGetElement ( ~json ; ~key ) ; "" )
							; ~counter = 0	
							; ~countValues = ValueCount ( ~values )
							; ~result = "[]"
						 ]; 
							~counter < ~countValues ; // condition to run while loop (only runs while condition is true)
						 [ logic = 1
							; ~counter	= ~counter + 1
							; ~value	= GetValue ( ~values ; ~counter )
							; ~emptiesRemoved	= JSONDeleteEmptyElements ( ~value )
							; ~result	= JSONSetElement ( ~result ; "[" & ~counter - 1 & "]" ; ~emptiesRemoved ; JSONGetElementType ( ~value ; "" ) )

						 ]; 
							~result
						 )
						 ; JSONArray ) 
					; ~isEmpty	; JSONDeleteElement ( ~result ; ~key ) 
					; ~result
				  )
 ]; 
	~result
)

Removes any empty elements from a JSON object or array of objects. Recursively removes any empty nested values.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSONDeleteEmptyElements ( json )

Comments

Support this website.

Support this website.