ValidateUKPostcodeFormat ( _postcode )

Checks whether a string is a valid UK postcode format. A fixed version of function "ValdidateUKPostcode" by Thomas Seidler

Be the first to rate this function Log in to vote

Ben - Show more from this author
realseeds
https://www.realseeds.co.uk

Sample input:

ValidateUKPostcodeFormat ("SA65 9SR")

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [
_postcode = Filter(Upper(_postcode); "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789") ;

_firstNumbers = Filter ( Left ( _postcode ; Length(_postcode)-3) ; "0123456789" ) ;

_postcodePrefixes = "¶AB¶AL¶B¶BA¶BB¶BD¶BF¶BH¶BL¶BN¶BR¶BS¶BT¶BX¶CA¶CB¶CF¶CH¶CM¶CO¶CR¶CT¶CV¶CW¶DA¶DD¶DE¶DG¶DH¶DL¶DN¶DT¶DY¶E¶EC¶EH¶EN¶EX¶FK¶FY¶G¶GIR¶GL¶GU¶GY¶HA¶HD¶HG¶HP¶HR¶HS¶HU¶HX¶IG¶IM¶IP¶IV¶JE¶KA¶KT¶KW¶KY¶L¶LA¶LD¶LE¶LL¶LN¶LS¶LU¶M¶ME¶MK¶ML¶N¶NE¶NG¶NN¶NP¶NR¶NW¶OL¶OX¶PA¶PE¶PH¶PL¶PO¶PR¶RG¶RH¶RM¶S¶SA¶SE¶SG¶SK¶SL¶SM¶SN¶SO¶SP¶SR¶SS¶ST¶SW¶SY¶TA¶TD¶TF¶TN¶TQ¶TR¶TS¶TW¶UB¶W¶WA¶WC¶WD¶WF¶WN¶WR¶WS¶WV¶YO¶ZE¶" ;
_matchedPrefix = FilterValues ( ¶ & Left(_postcode;Position(_postcode;_firstNumbers;0;1)-1) & ¶ ; _postcodePrefixes ) ;

_lastNumber = Filter( Middle(_postcode;Length(_postcode)-2;1) ; "0123456789" ) ;
_last2Chars = Filter( Right(_postcode;2) ; "ABDEFGHJLNPQRSTUWXYZ" ) ;


_valid = Case (
	Left(_postcode;4) = "BFPO"; 
	Let ( _rhs = Right(_postcode ; Length(_postcode)-4 ) ; 
               _rhs and Length(_rhs)<=4 and ( Filter ( _rhs ; "0123456789") = _rhs ) );
	
	// fail if not matched prefix or missing compulsory elements: compliant last two characters; first digit(s) and last digit
	not ( Length(_matchedPrefix) and Length(_lastNumber) and (Length(_last2Chars)=2) and Length(_firstNumbers) ) ; 0 ;

	/* AA9A 9AA */
	_matchedPrefix = "WC" or 
		(_matchedPrefix = "EC" and  _firstNumbers>0 and  _firstNumbers<5 ) or 
		Left(_postcode;4)= "SE1P" or 
		(_matchedPrefix="SW" and _firstNumbers = 1) ; 
	Length(_postcode)=7 and Length( Filter( Middle(_postcode;4;1) ; "ABEHMNPRVWXY" ) ) ;
	
	/* A9A 9AA */
	Length( FilterValues( Left(_postcode;3); "E1W¶N1C¶N1P" ) ) ; Length(_postcode)=6 and Length( Filter( Middle(_postcode;3;1) ; "ABCEFGHJKPSTUW" ) ) ;
	
	/* A9 9AA¶A99 9AA */
	Length( FilterValues ( _matchedPrefix ; "B¶E¶G¶L¶M¶N¶S¶W" ) ) ; Length(_postcode)=5 or Length(_postcode)=6 ;
	
	/* AA9 9AA¶AA99 9AA */
        Length(_postcode)=6 or Length(_postcode)=7 ; 1
)
] ;

_valid

)

I found on here a script by Thomas Siedler "ValidateUKPostcode" which looked awesome - but it had several syntax errors in it and did not work in FM19, not sure it could have ever worked as published as the case statement was missing its final value declaration, and a couple of functions appeared not to be filemaker syntax . .. I have fixed these errors and it appears to work now.
Caveat - I say 'appears' because I have not exhaustively checked the logic of the postcode matching algorithm, just fixed the code so it will run. However, applying it on our database of 188,000 customers correctly identified 1,300 with bad UK postcodes, so I am happy using it.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ValidateUKPostcodeFormat ( _postcode )

Comments

Support this website.

Support this website.