NameCase ( InName )

Use to proper case each part of a person's name.

Be the first to rate this function Log in to vote

Richard DeShong - Show more from this author
Logic Tools
http://logictools.com

Sample input:

NameCase ( "DESCOMBES" )

Sample output:

"DesCombes"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let([
   InName = TrimAll( InName ; 0 ; 1 ) ;
   InName = Case( Length( InName ) < 4  and  ( Exact( Upper( InName ) ; InName )  or  Exact( Lower( InName ) ; InName ) ) ; InName ; Proper( InName ) ) ;
   InName = Case( Exact( Upper( InName ) ; InName )  or Exact( Lower( InName ) ; InName )  ; Proper( InName ) ; InName ) ;

   // Single-Quote:  If none or at end, do nothing;  Else Proper() before and after:
   ~QPos = Position( InName ; "'" ; 1 ; 1 ) ;
   InName = Case( ~QPos = 0  or  ~QPos >= ( Length( InName ) - 1 ) ; InName ; Proper( Left( InName ; ~QPos - 1 ) ) & "'" & Proper( Middle( InName ; ~QPos + 1 ; 100 ) ) ) ;

   // Mc w/o space after:  Proper( both parts)
   ~IsMc = Left( InName ; 2 ) = "Mc"  and  Left( InName ; 3 ) <> "Mc " ;
   InName = Case( not ~IsMc ; InName ; "Mc" & Proper( Middle( InName ; 3 ; 100 ) ) ) ;

   // If name is just initials, then Upper():
   ~ListInitials = List( 
      "AC¶AJ¶BJ¶CJ¶DJ¶EJ¶JB¶JP¶JW¶KT¶PR¶RJ¶TD¶TJ" ;
      "A.C.¶A.J.¶B.J.¶C.J.¶D.J.¶E.J.¶J.B.¶J.P.¶J.W.¶K.T.¶P.R.¶R.J.¶T.D.¶T.J."
   );
   ~IsInitials = ListExist( ~ListInitials ; InName ) ;
   InName = Case( not ~IsInitials ; InName ; Upper( InName ) ) ;

   // FixName used if Proper() does not work properly:
   ~FixNames = "+DesCombes+maAne'+Am'ra+Anoa'i+Chana'e" &
      "+De'eric+De'ondre+De'zhon+DiMeco+Fa'atatala" &
      "+Ja'marcus+Ja'vion+Jash'anae+Ka'imi+Kamana'o" &
      "+Ke'alohilani+Ku'ulei+Ma'afala+Machray+Mchombo+OConnell" &
      "+Pau'u+Su'a+Ta'amilo+Te'o+" ;
   ~FixPos = Position( ~FixNames ; "+" & InName & "+" ; 1 ; 1 ) ;
   InName = Case( ~FixPos = 0 ; InName ; Middle( ~FixNames ; ~FixPos + 1 ; Length( InName ) ) )
];
   InName
)
/*
   Change InName to "Proper" case.
   Use separately on each name part: first, middle, last.
   When you find an exception, just add it the ~FixNames list.
*/

The Proper() function does not properly handle some names. This function attempts to do so.
You should use it separately on each name part: first, middle, last.

NOTE: There are no fixed name rules for capitalizing characters within a name. As an example, I have seen people want their lastname as "MacDonald" and another that wants "Macdonald". So there is no rule in this CF for "Mac". But all that I've come across with "Mc" want the 3rd character capitalized, except for "Mchombo" - which is why Mchombo is in the ~FixNames list.

IMPORTANT NOTE: This uses another custom function: ListExist(), which is at:
https://www.briandunning.com/cf/1701
or can be replaced by: not IsEmpty ( FilterValues ( InList ; InValue ) )

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

NameCase ( InName )

Comments

Support this website.

Support this website.