list.pattern_filter ( _list ; _value ; _case_sensitive )

Filters list values by text pattern with minimal recursion

Average rating: 5.0 (1 vote) Log in to vote

Mohamed Tawfiq - Show more from this author
CE
https://mhtawfiq.github.io/

Sample input:

list.pattern_filter ( "ABCD¶DDFG¶GGfG¶FFGG" ; "FG" ; 1 )

Sample output:

DDFG
FFGG

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// list.pattern_filter ( _list ; _value ; _case_sensitive )
// 20240502
// Mohamed H. Tawfiq - mhtawfiq@gmail.com
// Description: Filters list values by text pattern with minimal recursion
// Return: Matching list values if found, otherwise empty
// _list: Return delimited value list
// _value: Text pattern to find in _list, should not contain ¶
// _case_sensitive: Boolean | Case sensitive matching

While(
	[
		_list = _list & ¶;
		_list = If(
			_case_sensitive;
			Substitute( _list; _value; _value & "!@#$" );
			_list
		);
		_list_l = Length( _list );
		_value = If( _case_sensitive; _value & "!@#$"; _value );
		line_r = "";
		p_right = 1;
		p_right_l = Position( _list; _value; _list_l; - 1 )
	];
	p_right < p_right_l;
	[
		p = Position( _list; _value; p_right; 1 );
		p_left = Position( _list; ¶; p; - 1 );
		p_right = Position( _list; ¶; p; 1 );
		line = Middle( _list; p_left + 1; p_right - p_left - 1 );
		line_r = If( IsEmpty( line_r ); line; line_r & ¶ & line )
	];
	Substitute( line_r; "!@#$"; "" )
)

A rewrite of filterLines() function using While() and minimal recursion.

Instead of processing the list line by line it finds the first matching line, jumps to the next line, find the next matching line and so on.

This means that if there are only 4 matches in a list of 20k+ lines, we only need 4 recursions to find them instead of 20k+ making it much faster.

Comments

		Ibrahim Bittar Torres, Eikonsys, S.A. de C.V. May 19, 2024
Works really great! Thank you very much for this CF

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

list.pattern_filter ( _list ; _value ; _case_sensitive )

Comments

Support this website.

Support this website.