cfCourtStyle ( plaintiffs, defendants, rightTop, rightMiddle, rightBottom )

Style for top of a legal document to be filed in court

Average rating: 5.0 (1 vote) Log in to vote

Robert D Trammel - Show more from this author
https://www.linkedin.com/in/robertdtrammel/

Sample input:

cfCourtStyle( "John Doe"; "Mega Corp¶Mini Corp"; "IN THE JUSTICE COURT"; "DISTRICT 1-2"; "DALLAS COUNTY, TEXAS" )

Sample output:

JOHN DOE                             §    IN THE JUSTICE COURT
    Plaintiff,                       §
                                     §
VS.                                  §    DISTRICT 1-2
                                     §
MEGA CORP; and                       §
MINI CORP                            §
    Defendants.                      §    DALLAS COUNTY, TEXAS

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*********
Created to create a more dynamic styling to accommodate for plaintiffs, defendants and courts with longer or shorter names. Items on the right are wrapped based on items on the left. You can change the divider or column size, but this seems to satisfy data merges into Word documents.
DEPENDENCIES
   Custom Function: cfWordWrap
*********/

Let([
   leftColumnMax = 39;
   rightColumnMax = leftColumnMax;
   divider = "    §    ";

   plaintiffsWrapped = While([
      n = 1; plaintiffLineCt = ValueCount( plaintiffs ); output = ""
   ]; n <= plaintiffLineCt ;[
      output = List( output; Upper( cfWordWrap( GetValue( plaintiffs; n ); leftColumnMax ) ) );
      n = n + 1
   ]; output );

   //Defendant Data
   defendantsWrapped = While([
      d = 1; defendantLineCt = ValueCount( defendants ); output = ""
   ]; d <= defendantLineCt ;[
      output = List( output; cfWordWrap( Upper( GetValue( defendants; d ) ) & If( d < defendantLineCt; "; and" ); leftColumnMax ) ) ;
      d = d + 1
   ]; output );

   //Left Column
   //This needs to be smart enough to break on word wrap and grow downward
   styleLeft = List(
      plaintiffsWrapped;
      "    Plaintiff,";
      " ";
      "VS.";
      " ";
      defendantsWrapped;
      "    Defendant" & If ( ValueCount( defendants ) < 2 ; "." ; "s." );
   );

   styleLeftMiddle = Round( ValueCount( styleLeft )/ 2; 0 ); //The number of the middle line
   
   //Right Column
   styleRightTopline = cfWordWrap ( rightTop; rightColumnMax );
   rightToplineMax = ValueCount( styleRightTopLine );

   styleRightMiddleLine = cfWordWrap( rightMiddle; rightColumnMax );
   rightMiddleLineMax = ValueCount( styleRightMiddleLine );

   styleRightBottomLine = cfWordWrap( rightBottom; rightColumnMax );
   rightBottomlineMax = ValueCount( styleRightBottomLine );

   //Loop through each line of the left style and append the corresponding right line
   styleTogether = While([
         styleLineCt = ValueCount( styleLeft );
         i = 1; middleN = 0; bottomN = 0; output = ""
      ]; i <= styleLineCt ;[

         middleN = middleN + If( i >= styleLeftMiddle and i < styleLeftMiddle + rightMiddleLineMax ; 1 ); //Increment lines when we get to the middle

         bottomN = bottomN + If( i > styleLineCt - rightBottomLineMax; 1 ); //Increment lines when we get to the start of the bottom

         styleRightLine = Case(
            i <= rightToplineMax; GetValue( styleRightTopLine; i );
            i >= styleLeftMiddle and i < styleLeftMiddle + rightMiddleLineMax; GetValue( styleRightMiddleLine; middleN );
            i > styleLineCt - rightBottomLineMax; GetValue( styleRightBottomLine; bottomN );
            " "
         );

         output = List( output;
            cfPadSpaces( GetValue( styleLeft; i ) ; leftColumnMax; "Left") & divider & styleRightLine
         );

         i = i + 1
      ]; 
      Substitute( output; [" "; Char( 160 )]) //Replace regular spaces with unicode 160, non-breaking spaces for Microsoft Word
   )
];
   styleTogether & "¶" //Add a line break after the style
)

Created to create a more dynamic styling to accommodate for plaintiffs, defendants and courts with longer or shorter names. Items on the right are wrapped based on items on the left. You can change the divider or column size, but this seems to satisfy data merges into Word documents. This can take a list of plaintiffs or a single plaintiff, and a list of defendants, or a single defendant. The left column will wrap and resize, and the right column will wrap using the space created by the left column. This satisfied all of the cases we had, but I think it would probably be beneficial to figure out how to make the left side resize in the event that the data in the right column needs more rows.

Comments

		Robert D Trammel Aug 20, 2024
This was difficult to work out. But basically it's a manual way to create two columns of text. Specifically for styling on legal documents. I hope this can help someone to not have to work this out.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfCourtStyle ( plaintiffs, defendants, rightTop, rightMiddle, rightBottom )

Comments

Support this website.

Support this website.