JSON.OmitArrayValues

This function will allow you to omit a list of values from an array using values from a second "Omit" array.

Be the first to rate this function Log in to vote

Kyle Williams - Show more from this author
Augusto Digital
https://www.youtube.com/channel/UCpJlB7cmVNMjbjgY96MEsng

Sample input:

JSON.OmitArrayValues ( "[1,2,3,4]" ; "[4,2]" )
JSON.OmitArrayValues ( "[\"a1\",\"2b\",\"3\",\"4\"]" ; "[4,2]" )

Sample output:

[1,3]
["a1","2b",\"3\"]

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*	Author:		Kyle Williams
	Date:		2/13/2025
	Purpose: 	To iterate through the source array and remove any values found in the second array
	Dependencies:	CF: isNumeric()	
*/

While([  
	 ListOfIDs = JSONListValues ( arrSource; "" )
	;OmitIDs = JSONListValues ( arrOmit ; "" )
	;Count = ValueCount( ListOfIDs )
	;index = 1
	;filteredList = ""
	;isAlpha = 0
	;IsAlphaCt = 0
];  
    index ≤ Count
;[  
	 currentValue = GetValue( ListOfIDs ; index )
	;isAlpha = not isNumeric( currentValue )
	;IsAlphaCt = Sum( IsAlphaCt; isAlpha )
	;filteredList = If( IsEmpty( FilterValues( currentValue ; OmitIDs ) ) ;
                          List( filteredList ; currentValue ) ;
                          filteredList )
	;index = index + 1
];
	If( IsAlphaCt
		;"[\"" & Substitute( filteredList ; ¶ ; "\",\"" ) & "\"]"	
		;"["    & Substitute( filteredList ; ¶ ; "," )       & "]"
	)
)

I recently worked on an API where I had to use employee ids from FullSlate's calendar scheduling app. The api call required employee ids in order to find records for availability, personal breaks, and appointments for each employee.. I found I was able to get a full list of the employees but many in the list had been deleted over time.

Because of this I needed to omit many of the ids from the array I was getting. This function was created to solve this need to produce a more refined list of ids for my api calls. I thought this might be a useful function for the community so I'm sharing it here :)

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSON.OmitArrayValues

Comments

Support this website.

Support this website.