JSONtoJSONSetElement

Convert JSON into a JSONSetElement calculation

Be the first to rate this function Log in to vote

Jason Wood - Show more from this author
Define Database
https://www.definedatabase.com

Sample input:

JSONtoJSONSetElement ( $json )

/* $json =

{
"string": "Hello, world!",
"number": 42,
"boolean": true,
"nullValue": null,
"array": [1, "two", false, null, {"nestedObject": "insideArray"}],
"object": {
"level1Key": "Level 1 value",
"nestedObject": {
"level2Key": 3.14,
"anotherNestedObject": {
"level3Key": {
"deepBoolean": false,
"deepArray": [true, null, {"deepestKey": "Deep inside"}]
}
}
}
}
}

*/

Sample output:

JSONSetElement ( "" ;
[ "array[0]" ; 1 ; JSONNumber ];
[ "array[1]" ; "two" ; JSONString ];
[ "array[2]" ; 0 ; JSONBoolean ];
[ "array[3]" ; "" ; JSONNull ];
[ "array[4].nestedObject" ; "insideArray" ; JSONString ];
[ "boolean" ; 1 ; JSONBoolean ];
[ "nullValue" ; "" ; JSONNull ];
[ "number" ; 42 ; JSONNumber ];
[ "object.level1Key" ; "Level 1 value" ; JSONString ];
[ "object.nestedObject.anotherNestedObject.level3Key.deepArray[0]" ; 1 ; JSONBoolean ];
[ "object.nestedObject.anotherNestedObject.level3Key.deepArray[1]" ; "" ; JSONNull ];
[ "object.nestedObject.anotherNestedObject.level3Key.deepArray[2].deepestKey" ; "Deep inside" ; JSONString ];
[ "object.nestedObject.anotherNestedObject.level3Key.deepBoolean" ; 0 ; JSONBoolean ];
[ "object.nestedObject.level2Key" ; 3.14 ; JSONNumber ];
[ "string" ; "Hello, world!" ; JSONString ]
)

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
==================================================================
NAME:
	JSONtoJSONSetElement ( json )

PURPOSE:
	Create a JSONSetElement calculation for the provided JSON object.
       
PARAMETERS:
	json | object

RETURNS:
	(STRING) JSONSetElement Calculation

NOTES & DEPENDENCIES:
	None

CONTRIBUTORS
	JW / Jason Wood / Define Database / www.definedatabase.com

CHANGELOG
	2019-10-19 JW Created
	2025-02-21 JW Added JSON validation
==================================================================
*/

If ( Left ( JSONGetElement ( json ; "xalsdjfaluksdfjlnzvoiysehsz_very_unlikely_key_name" ) ; 3 ) ≠ "? *" ;

While ( [ 
  ~json = json ;
  ~i = 0;
  ~keys = JSONListKeys ( ~json ; "" );
  ~keys = If ( GetValue ( ~keys ; 1 ) = 0 and GetValue ( ~keys ; ValueCount ( ~keys ) ) = ValueCount ( ~keys ) - 1 ; "[" & Substitute ( ~keys ; "¶" ; "]¶[" ) & "]" ; ~keys );
  ~key = "";
  ~isMore = "";
  ~moreKeys = ""
 ] ; 
  ~i < ValueCount ( ~keys )
 ; [ 
  ~i = ~i + 1;
  ~key = GetValue ( ~keys ; ~i );
  ~moreKeys = JSONListKeys ( ~json ; ~key );
  ~isMore = GetAsBoolean ( ValueCount ( ~moreKeys ) );
  ~isArray = If ( ~isMore ; GetValue ( ~moreKeys ; 1 ) = 0 and GetValue ( ~moreKeys ; ValueCount ( ~moreKeys ) ) = ValueCount ( ~moreKeys ) - 1);
  ~moreKeys = If ( ~isMore ; 
    If ( ~isArray ;
        ~key & "[" & Substitute ( ~moreKeys ; "¶" ; "]¶" & ~key & "[" ) & "]" ;
        ~key & "." & Substitute ( ~moreKeys ; "¶" ; "¶" & ~key & "." )
    )
  );
  ~i = If ( ~isMore ; ~i - 1 ; ~i );
  ~keys = If ( ~isMore ; Substitute ( "¶" & ~keys & "¶" ; "¶" & ~key & "¶" ; "¶" & ~moreKeys & "¶" ) ; "¶" & ~keys & "¶" );
  ~keys = Middle ( ~keys ; 2 ; Length ( ~keys ) - 2 )
 ] ; 
  
  While ( [
    ~i = 0;
    ~json = ~json;
    ~keys = ~keys;
    ~key = "";
    ~quote = "";
    ~jsontype = "JSONString";
    ~jsonTypeFunctionIsInstalled = JSONGetElementType ( "{}" ; "" ) = 3;
    ~result = "JSONSetElement ( \"\" ;"
   ] ;
    ~i < ValueCount ( ~keys )
   ; [
    ~i = ~i + 1;
    ~key = GetValue ( ~keys ; ~i );
    ~jsontype = If ( ~jsonTypeFunctionIsInstalled ; Choose ( JSONGetElementType ( ~json ; ~key ) ; "" ; "JSONString" ; "JSONNumber" ; "jSONObject" ; "JSONArray" ; "JSONBoolean" ; "JSONNull" ; "Error" ) ; ~jsontype );
    ~quote = If ( ~jsontype = "JSONString" or ~jsontype = "JSONNull" ; "\"" ; "" );
    ~result = List ( ~result ; "  [ \"" & ~key & "\" ; " & ~quote & JSONGetElement ( ~json ; ~key ) & ~quote & " ; " & ~jsontype & " ]" & If ( ~i < ValueCount ( ~keys ) ; ";" ; "¶)" ) )
   ];
    ~result
   )

)

; "" ) //Return empty string for invalid JSON

The intended use is as a developer tool, for situations where you have sample JSON and need to create a JSONSetElement calculation to create a similar JSON object.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSONtoJSONSetElement

Comments

Support this website.

Support this website.