HSBtoRGB ( hueDegrees ; satPercentage ; briPercentage )

Converts color from HSB/HSV values to RGB percentages.

Average rating: 4.0 (39 votes) Log in to vote

Joe Rovang - Show more from this author

Sample input:

HSBtoRGB ( 240 ; 1 ; .5 )

Sample output:

0
0
.5

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [

pHue = Mod ( GetAsNumber ( hueDegrees ) ; 360 ) ; 
pSat = GetAsNumber ( satPercentage ) ; 
pBri = GetAsNumber ( briPercentage ) ; 

_H = Mod ( Floor ( pHue / 60 ) ; 6 ) ; 
_F = ( pHue / 60 ) - _H ; 
_P = pBri * ( 1 - pSat ) ; 
_Q = pBri * ( 1 - ( _F * pSat ) ) ; 
_T = pBri * ( 1 - ( ( 1 - _F ) * pSat ) ) ; 

vRed = Case ( ( pSat = 0 ) ; ( pBri ) ; Choose ( _H ; pBri ; _Q ; _P ; _P ; _T ; pBri ) ) ; 
vGreen = Case ( ( pSat = 0 ) ; ( pBri ) ; Choose ( _H ; _T ; pBri ; pBri ; _Q ; _P ; _P ) ) ; 
vBlue = Case ( ( pSat = 0 ) ; ( pBri ) ; Choose ( _H ; _P ; _P ; _T ; pBri ; pBri ; _Q ) )

] ; 

Case ( ( pHue ≥ 0 ) and ( pHue < 360 ) and ( pSat ≥ 0 ) and ( pSat ≤ 1 ) and ( pBri ≥ 0 ) and ( pBri ≤ 1 ) ; 

( vRed ) & "¶" & ( vGreen ) & "¶" & ( vBlue )

)
)

Parameters:
hueDegrees
satPercentage
briPercentage

This function converts the specified color from hue, saturation, and brightness/value (HSB/HSV) to RGB percentages. (Note that HSB/HSV is not the same as HSL!)

Note that while hue is expressed in degrees, all other values are expressed in decimals between 0 and 1, inclusively. To use the output RGB values in a TextColor function, you'd first need to multiply them by 255 and round to whole numbers.

I'm sorry to say that I don't actually understand the math behind the function - I translated it from formulas listed on Wikipedia.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HSBtoRGB ( hueDegrees ; satPercentage ; briPercentage )

Comments

Support this website.

Support this website.