SortArray_Merge ( leftList ; rightList ; sortDirection ; dataType )

Merge two sorted lists of text, number, date or time values

Average rating: 3.9 (37 votes) Log in to vote

Mogens Brun - Show more from this author
FM Integrator
http://filemakerintegrator.dk

Sample input:

"1
4
13"

and

"2
7
8"

Sample output:

1
2
4
7
8
13

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// Merge two sorted lists of text, number, date or time values
// Version: 1.01
// Parameters: "leftList" = left array. "rightList" = right array. "sortDirection" = [ "Asc" ; "Des" ] for ascending og descending sort. "dataType" = [ "Text" ; "Number ; " Date" ; "Time" ] where "Text" is default.
// Credit: Originally implemented in FileMaker custom function by Shaun Flisakowski Marts 2004 (www.clevelandconsulting.com)
// NOTE 1: Subfunction to "SortArray ( valueList ; sortDirection ; dataType )
// 05nov06 ; Mogens Brun ; FM Integrator ; mogens_brun@mac.com.

Let( [
         $LeftSize = ValueCount ( leftList ) ;
         $RightSize = ValueCount ( rightList )
         ] ; 
         Case (
               $LeftSize = 0 ; rightList ; 
               $RightSize = 0 ; leftList ; 
               Let (
                     [
                     $LeftValue = LeftValues ( leftList ; 1 ) ;
                     $RightValue = LeftValues ( rightList ; 1 ) ;
                     $LeftCompare = Case ( dataType = "Number" ; Let ( $RightCompare = GetAsNumber ( $RightValue ); GetAsNumber ( $LeftValue ) ) ; dataType = "Time" ; Let ( $RightCompare = GetAsTime ( $RightValue ) ; GetAsTime ( $LeftValue ) ) ; dataType = "Date" ; Let ( $RightCompare = GetAsDate ( $RightValue ) ; GetAsDate ( $LeftValue ) ) ; Let ( $RightCompare = $RightValue ; $LeftValue ) )
                     ] ; 
                     If ( If ( sortDirection = "Asc"; $LeftCompare ≤ $RightCompare ; $LeftCompare > $RightCompare ) ; $LeftValue & SortArray_Merge ( RightValues ( leftList ; $LeftSize - 1 ) ; rightList ; sortDirection ; dataType ) ; 
                     $RightValue & SortArray_Merge ( leftList ; RightValues ( rightList ; $RightSize - 1 ) ; sortDirection ; dataType )
                     )
              ) // Let 
       ) // Case $LeftSize/$RightSize
) // Let

Sub custom function to SortArray ( valueList ; sortDirection ; dataType )

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

SortArray_Merge ( leftList ; rightList ; sortDirection ; dataType )

Comments

Support this website.

Support this website.