TextFormatApply ( targetField ; sourceField )

Applies the first available style in "sourceField" to the contents of "targetField"

Average rating: 4.4 (33 votes) Log in to vote

David Graham - Show more from this author
Productive Computing, Inc.
http://www.productivecomputing.com/

Sample input:

TextFormatApply ( targetField ; sourceField )

Sample output:

targetField will be styled like the first style present in sourceField

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let( [ 

/* begin format style property list
Inspired by "CF  GetTextStyle" by Marco terrile 2006
Modified by David Graham - Productive Computing, Inc. - Jan 1, 2007. 
Eliminated additional CF dependencies; forced CSS into prop list that can be applied using Evaluate()
*/

extractCSSFromSource = GetAsCSS ( sourceField ) ; 
startAtPos = Position ( extractCSSFromSource ; "\"" ; 1 ; 1 ) + 1 ; 
length = Position ( extractCSSFromSource ; "\"" ; 1 ; 2 ) - 1 - startAtPos ; 
getCSSPropertyList = "font_family:;font_size:;color:;font_weight:plain+;font_style:;text_decoration:;line_through:;font_variant:;letter_spacing:;text_transform:;vertical_align:;" & 
Middle ( extractCSSFromSource ; startAtPos ; length ) ; // add placeholder properties with empty values to ensure that they always evaluate
stylePropertyList =
  Substitute ( 
    getCSSPropertyList ; 

    // convert CSS properties & values to proprietary property list format which more closely matches FMP style equivalents
    [ "letter-spacing: -2px" ; "letter-spacing: condense+" ] ; 
    [ "letter-spacing: 2px" ; "letter-spacing: extend+" ] ; 
    [ "line-through" ; "line-through=\"Strikethrough+" ] ; 
    [ "bold" ; "bold+" ] ; 
    [ "italic" ; "italic+" ] ; 
    [ "small-caps" ; "SmallCaps+" ] ; 
    [ "text-top" ; "Superscript+" ] ; 
    [ "text-bottom" ; "Subscript+" ] ; 
    [ "underline" ; "underline+" ] ; 
    [ "uppercase" ; "Uppercase+" ] ; 
    [ "lowercase" ; "Lowercase+" ] ; 
    [ "capitalize" ; "Titlecase+" ] ; 

    // convert remaining CSS to name/value pairs for ease in parsing
    [ ": " ; "=\"" ] ; 
    [ "'" ; "" ] ; 
    [ ":" ; "=\"" ] ; 
    [ ";" ; "\";¶" ] ; 
    [ "-" ; "_" ] 
  ) & "\""  ; 

// end format style property list

// begin Hex to RGB function

/* begin Hex to RBG function
Adapted from "cf_convertHexRGB" by Klemens Müller, www.klemenso.de
Modified by David Graham - Productive Computing, Inc. - Jan 1, 2007. 
Compressed code to reduce scrolling :-)
*/

  hexRange = "0123456789ABCDEF" ; 
  hexValue = Filter ( Evaluate( "Let( [ " & stylePropertyList & "] ; color )" ) ; hexRange ) ; 
  r1 = Position( hexRange ; Middle( hexValue ; 1 ; 1 )  ; 1 ; 1 ) - 1  ;
  r2 = Position( hexRange ; Middle( hexValue ; 2 ; 1 )  ; 1 ; 1 ) - 1  ;
  g1 = Position( hexRange ; Middle( hexValue ; 3 ; 1 )  ; 1 ; 1 ) - 1  ;
  g2 = Position( hexRange ; Middle( hexValue ; 4 ; 1 )  ; 1 ; 1 ) - 1  ;
  b1 = Position( hexRange ; Middle( hexValue ; 5 ; 1 )  ; 1 ; 1 ) - 1  ;
  b2 = Position( hexRange ; Middle( hexValue ; 6 ; 1 )  ; 1 ; 1 ) - 1  ;
  red = r1 * 16 + r2 ;
  green = g1 * 16 + g2 ;
  blue  = b1 * 16 + b2 ;

// end Hex to RGB function

// begin style extraction

  color = Evaluate( "RGB( " & red & " ; " &  green  & " ; " & blue & " )" ) ; 
  fontName = Evaluate( "Let( [ " & stylePropertyList & "] ; font_family )" )  ; 
  styles = Evaluate(  "Let( [ " & stylePropertyList & "] ; font_weight & font_style & text_decoration & letter_spacing & line_through & font_variant & vertical_align & text_transform & \"plain\" )" ) ; // NB, plain is ignored when other styles are present 
  fontSizeTest = Evaluate( "Let( [ " & stylePropertyList & "] ; GetAsNumber ( font_size ) )" ) ; 
  fontSize = Case( PatternCount ( styles ; "Superscript" ) or PatternCount ( styles ; "Subscript" ) ; fontSizeTest * 2 ; fontSizeTest ) ;

// end style extraction

// apply styling

  stripAllFormatting = TextFormatRemove ( targetField ) ;
  stylesApplied = TextStyleAdd ( stripAllFormatting ; Evaluate( styles ) ) ; 
  fontApplied = TextFont ( stylesApplied ; fontName ) ; 
  colorApplied = TextColor ( fontApplied ; color )
] ; 

  TextSize ( colorApplied ; fontSize ) // size is the final application

)

If you ever wanted to be able to style field text based on the styling present in another field, then this is for you.

Some sample uses:

1. Create user-definable report styles for common page sections (e.g., Title, Subtitle, etc.), and apply to reports dynamically.

2. Style multiple parts of a single document to be the same as another. For instance, if you have separate fields to store a letter body and closing, you can se the style of the closing field equal to the body field.

This CF was inspired by the work of others, but my goal was to create one CF that could do the work of extracting and applying styles without any additional dependencies.

NB, nearly every style variation is supported. I've noticed that it doesn't work with word underline and double underline. You might find some other obscure variations that don't translate.

Comments

		Bruce Robertson Feb 5, 2010
All you need is this expression: substitute( sourceField; sourceField; targetField )

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TextFormatApply ( targetField ; sourceField )

Comments

Support this website.

Support this website.