cfColorByIndent ( pText ; pIndentChar ; pRgbColorList )

emphasizing thread-depths in a forum or indentations in text

Average rating: 4.2 (39 votes) Log in to vote

Tammo Fornalik / Felix Hausberner
dbyte solutions
http://www.dbyte-solutions.com

Sample input:

cfColorByIndent( ">Hello!¶>>What's up?¶¶>>>Look: 5>4¶Ah."; ">"; RGB( 0; 0; 255 ) &¶& RGB( 0; 255; 0 ) &¶& RGB( 255; 0; 0 ) )

Sample output:

[BLUE] >Hello
[GREEN] >>What's up?
[RED] >>>Look: 5>4
[FIELD COLOR] Ah.

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//cfColorByIndent (pText ; pIndentChar ; pRgbColorList) =

Let(
[
vLineCnt = ValueCount( pText ) ;
vThisLine = TextColorRemove( LeftValues( pText ; 1 ) ) ; //reset the line's color
vFirstDiff = Left( Substitute( vThisLine; pIndentChar; "" ); 1) ; //get the 1st character not being the indent char
vDepth = Case( Left( vThisLine; 1 ) <> pIndentChar; 0; Position( vThisLine; vFirstDiff; 1; 1 ) -1 ) ; //final indent depth

vColCnt = ValueCount( pRgbColorList ) ;
vRotMult = Ceiling( vDepth / vColCnt ) -1 ; //get multiplier for rotating the color list

//get final color from color list. rotate color list if indent depth exceeds number of chosen colors. use "evaluate"!
vOut = Case( vDepth = 0; vThisLine; TextColor( vThisLine ; Evaluate( GetValue( pRgbColorList ; vDepth - vRotMult * vColCnt ) ) ) )
];

Case(
vLineCnt>1;
vOut & cfColorByIndent( RightValues( pText ; vLineCnt-1 ) ; pIndentChar ; pRgbColorList ); vOut
) //end case

) //end let

/*
authors: tammo fornalik, felix hausberner
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
parameters:
pText = the given text.
pIndentChar = character or string which determines the depth of indentation/thread-depth and therefore the line's color.
pRgbColorList = rgb specifications as a return delimited list [syntax: RGB( red; green; blue ) &¶& RGB( red; green; blue )...]

calling syntax:
cfColorByIndent( ">Hello!¶>>What's up?¶¶>>>Look: 5>4¶Ah."; ">"; RGB( 0; 0; 255 ) &¶& RGB( 0; 255; 0 ) &¶& RGB( 255; 0; 0 ) )
or
cfColorByIndent( Message_t; ">"; zz_ColorList_gt ), given Message_t is a text-field and zz_ColorList_gt is a (globally stored) multiline-field.
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
great for emphasizing thread-depths in a forum or indentations in text. arbitrary color-lists.
colors every line by counting the determined indention character, which is always at the start of a line (also several times).
thereby it does not matter how often the character occurs in the line altogether, but only, how often the character occurs BEFORE
the first "regular" character of the line.
the highest indentation-level (no indention) is left in the standard text color for the appropriate field.
as soon as the indentation count exceeds the count of determined colors, the color list rotates.
also permitted is a multiline-rgb-list list of a global field.
*/

great for emphasizing thread-depths in a forum or indentations in text. arbitrary color-lists.
colors every line by counting the determined indention character, which is always at the start of a line (also several times).
thereby it does not matter how often the character occurs in the line altogether, but only, how often the character occurs BEFORE
the first "regular" character of the line.
the highest indentation-level (no indention) is left in the standard text color for the appropriate field.
as soon as the indentation count exceeds the count of determined colors, the color list rotates.
also permitted is a multiline-rgb-list list of a global field.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfColorByIndent ( pText ; pIndentChar ; pRgbColorList )

Comments

Support this website.

Support this website.