MailMergePlus ( text ; highlight )

Mailmerge function that preserves formatting of source text

Average rating: 4.0 (45 votes) Log in to vote

Peter Vinogradov - Show more from this author

Sample input:

MailMergePlus ( "Dear <>, Welcome to <>..."; 1)

Sample output:

Dear John (in blue), Welcome to Cambridge University (in blue)...

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*  MailMergePlus ( text ; highlight)
3-31-2008, Peter Vinogradov
Recursive function that replaces bracket-enclosed (<<>>) formulae or field references with evaluated results.
This method preserves formatting of the source text (including format of the merge field/formula based on the format of the first bracket).
The "highlight" switch is used to return a blue coloration for the results of any merge fields/formulae. If this parameter is set to null ( "" ), then no special formatting is applied.
*/


Let (

[

r = 50; g=50; b=230;   //set MF highlight colors

MFPos =Position(text;"<<";1;1);
MFLen=Position(Text;">>";1;1)+2-MFPos;
MF=Middle(Text;MFPos+2;MFLen-4);
highlightMF = If (highlight;  TextColor ( Evaluate(MF);  RGB(r;g;b) ) ; Evaluate(MF) );
newtext = If (MFPos ; Replace ( text; MFPos;MFLen ; highlightMF ) ; text ) ;  //revised 3-09 to account for text with no Merge Fields

moreMfs = PatternCount( Filter ( newtext ; "<<>>") ; "<<>>" )

];

If ( moreMfs ; MailMergePlus (newtext ;highlight) ; newtext )

)

A recursive function that replaces bracket-enclosed (<<>>) formulae or field references with evaluated results. Works similarly to Mike Duncan's "MailMerge" function (http://www.briandunning.com/cf/438).

Because it does not evaluate the entire output string, This method preserves formatting of the source text (including the format of the merge field/formula based on the format of the first bracket).

The "highlight" switch is used to return a blue coloration for the results of any merge fields/formulae. If this parameter is set to null ( "" ), then no special formatting is applied. This feature is useful for giving users a way to easily check the output of their merge letter.

Edit: Oops, just discovered that my merge formula is very similar (coincidentally, I swear) to the one in this function: http://www.briandunning.com/cf/826
That one uses getfield() instead of evaluate, which is a good way of restricting the functionality so that users can't execute arbitrary calcs.
Edit 3-12-09: Thanks to Nick Lightbody for pointing out that the original formula chopped off the first two characters of the text if no merge fields <<>> are present. I have revised accordingly.

Comments

		Nick Lightbody, Deskspace Systems Limited Mar 12, 2009
Very useful being able to switch the hilite on and off. However - it doesn't quite work right if the first characters in the string are not "<<" when it removes the first two characters.

		Thomas Seidler, London Apr 20, 2012
You've done a top function here Peter, only barbarians won't appreciate it, I removed highlight thing, but ability to quickly and properly evaluate anything in <<merge brackets>> is awesome. I'm using it for regular emails with multiple occurences of the same date in various formats - I used to keep not updating one or another of the dates - about 5 places in email (subject, headers, body etc), and now I just have a date in a field, and use some form of <<FormatTimestamp(myDate;"M jS")>> etc. Very very useful. I would have had to write it myself otherwise. Thanks, Tom

		Mike Feb 13, 2013
Fantastic cf. However, it's easy to send this into an infinite loop: field: "Hello World <<field>>" MailMergePlus ( "<<field>>" ; "" ) One possible solution: In "newtext = ", instead of just highlightMF, escape << and >>: Substitute ( highlightMF ; ["<<" ; "\\<\\<" ] ; [">>" ; "\\>\\>" ] ) Then at the end, unescape << and >> If ( moreMfs ; MailMergePlus (newtext ;highlight) ; Substitute ( newtext ; ["\\<\\<" ; "<<" ] ; ["\\>\\>" ; ">>" ] ) )

		mark woytovich, ignotum inc Dec 18, 2019
Weird... I'm having a problem with this CF in a newly created file. It will not "merge" when there is >1 set of <> merge elements. I have been using this CF elsewhere with great success. For example this yields nothing, but when I remove <> for example, it works for what is left. <> Message goes here. <> Anyone have any ideas?

		mark woytovich, ignotum inc Dec 18, 2019
so that when I entered my placeholders surrounded by << and >> it substituted out what I typed... I hope you understand what was supposed to be the example.

		mark woytovich, ignotum inc Dec 18, 2019
And I just found that the "MailMerge" CF works....

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

MailMergePlus ( text ; highlight )

Comments

Support this website.

Support this website.