cfISRC ( pMode ; pISRC_Code ; pRGB_OnError )

ISRC formatting / validating

Average rating: 4.2 (39 votes) Log in to vote

Tammo Fornalik / Felix Hausberner
dbyte solutions
http://www.dbyte-solutions.com

Sample input:

[1] cfISRC("format"; "FRZ039800212"; RGB(255;0;0) )

[2] cfISRC("format"; "2GHH3276654F"; RGB(255;0;0) )

[3] cfISRC("check"; "2GHH3276654F"; RGB(255;0;0) )

Sample output:

[1] FR-Z03-98-00212
[2] •WRONG INPUT
[3] 1

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//cfISRC ( pMode; pISRC_Code; pRGB_OnError )

/*
version: 2008/05/23, tammo fornalik, felix hausberner
ISO 3901:2001. ISRC example (formatted): FR-Z03-98-00212 .
according to the ISRC specs, there is no checksum. so the verification part is an approximation.
pMode = "format": formats given string to readable ISRC or throws an error text if input is not correct.
pMode = "check": tests on correct input only. returns 1 if input is incorrect, 0 if correct (!)
*/

Case( not IsEmpty( pISRC_Code );

Let(
[
//configure given ISRC standards
vIn = Upper( TextFormatRemove( pISRC_Code ));
vAlpha = "ABCDEFGHIJKLMNOPQRSTUVWXYZ";
vInteger = "0123456789";
vAlphanumeric = vAlpha & vInteger;
vInFiltered = Filter( vIn ; vAlphanumeric );
vLenAlwBlck = "2¶3¶2¶5";  // array: define max length for each of the 4 blocks.
vSepBlckAt = "0¶3¶6¶8";  // array: define position of separation for each of the 4 blocks.
vLenAlwAll = Evaluate( Substitute( vLenAlwBlck ; "¶" ; "+" ) ); //allowed overall raw-length, calculated sum of blocks length.

// init utility vars
vMode = pMode;
vRGB = pRGB_OnError;
vSep = "-";
vErrorText = "•WRONG INPUT";

// decompose string and filter out mismatching datatypes
vBlock1 = Filter( Middle( vInFiltered ; GetValue( vSepBlckAt ; 1 ) ; GetValue( vLenAlwBlck ; 1 ) ) ; vAlpha );
vBlock2 = Filter( Middle( vInFiltered ; GetValue( vSepBlckAt ; 2 ) ; GetValue( vLenAlwBlck ; 2 ) ) ; vAlphanumeric );
vBlock3 = Filter( Middle( vInFiltered ; GetValue( vSepBlckAt ; 3 ) ; GetValue( vLenAlwBlck ; 3 ) ) ; vInteger );
vBlock4 = Filter( Middle( vInFiltered ; GetValue( vSepBlckAt ; 4 ) ; GetValue( vLenAlwBlck ; 4 ) ) ; vInteger );

// test for max overall length
vTooLong = Length( vInFiltered ) > vLenAlwAll;

// test for datatype- and/or length-errors for each block
vBlock1Err = Length( vBlock1 ) ≠ GetValue( vLenAlwBlck ; 1 );
vBlock2Err = Length( vBlock2 ) ≠ GetValue( vLenAlwBlck ; 2 );
vBlock3Err = Length( vBlock3 ) ≠ GetValue( vLenAlwBlck ; 3 );
vBlock4Err = Length( vBlock4 ) ≠ GetValue( vLenAlwBlck ; 4 );

// define error flag
vIsError = vTooLong or vBlock1Err or vBlock2Err or vBlock3Err or vBlock4Err;

// fire
vOut =
	Case(
	vMode = "format"; Case( not vIsError; vBlock1 & vSep & vBlock2 & vSep & vBlock3 & vSep & vBlock4; TextColor( vErrorText ; vRGB ) );
	vMode = "check"; vIsError;
	"ERROR, CHECK FUNCTION!" )
];
vOut
) //end let

; "" ) //end case

ISO 3901:2001. ISRC example (formatted): FR-Z03-98-00212 .

according to the ISRC specs there is no checksum, so the verification part is an approximation.

pMode = "format": formats given string to readable ISRC or throws an error text if input is not correct.
pMode = "check": tests on correct input only. returns 1 if input is incorrect, 0 if correct (!)

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfISRC ( pMode ; pISRC_Code ; pRGB_OnError )

Comments

Support this website.

Support this website.