cfCode128 ( pString ; pCodeSet )

composes the final barcode Code128 of symbology A,B or C from a given alphanumeric string.

Average rating: 4.2 (51 votes) Log in to vote

Tammo Fornalik / Felix Hausberner
dbyte solutions
http://www.dbyte-solutions.com

Sample input:

cfCode128 ( "SBM16672_2008_08_25"; "B" )

Sample output:

"SBM16672_2008_08_25" as Code128B including checksum and start/stop tags (viewable with IDAutomation Code128 fonts)

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
cfCode128 ( pString; pCodeSet )

---use with FM version >= 10---
composes the final barcode Code128 of symbology A,B or C from a given alphanumeric string.
includes the checksum of the string (modulo 103) as well as start/stop characters.
this CF is meant to be used with barcode font "IDAutomationC128..."
http://www.advancemeants.com/code128fonts/download.htm

automatic switching between variants A,B,C within a single barcode is not yet supported.

pString: string to be used as a barcode.
pCodeSet: "A" or "B" or "C" are expected.
local var $i stores the actual count of loops.
be careful, $i var should not be used in a script running at the same time.
all vars (although locally stored) should be destroyed when the process is done.

author: tammo fornalik / felix hausberner, dbyte solutions, 01.06.2008
changes: 10.01.2009, Code() and Char() are now native functions in FM10, replaced references to CFs which did that job.
type: recursive
dependencies: none
call like: cfCode128( "SBM16672_2008_08_25"; "B" )
*/

//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> String is empty -> no output
Case( IsEmpty( pString ); ""

//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> CodeSet A, B
; pCodeSet = "A" or pCodeSet = "B";

  Let(
  [
  vInitOnce = Case( IsEmpty( $i );
        //the following inits are only processed during initial call
        Let(
        [
        $C128_Start = Char( Case( pCodeSet = "A"; 203; pCodeSet = "B"; 204; 0 ) ); //defined by C128 specs
        $C128_Stop = Char( 206 ); //defined by C128 specs
        $DataToEncode = Trim( pString );
        $WeightedTotal = Code( $C128_Start ) -100; //font specific
        $C128_CheckDigit = "w"; //font specific, on internal error
        $i = 0
        ]; "" ); //end let
      "" ); //end case

  $i = $i +1;
  //get the value of each character. calculate the WeightedTotal for modulo 103 checksum.
  vCurrentChar = Code( Middle( $DataToEncode; $i; 1 ) );
  vCurrentVal = Case( vCurrentChar < 135; vCurrentChar -32; vCurrentChar > 134; vCurrentChar -100 );
  vCurrentVal = vCurrentVal * $i;
  $WeightedTotal = $WeightedTotal + vCurrentVal
  ];

  Case(
    $i < Length( $DataToEncode ); cfCode128( $DataToEncode; pCodeSet ); //recursion
      Let(
      [
      //divide the WeightedTotal by 103 and get the remainder, this is the CheckDigitValue
      vChkDigitVal = Mod( $WeightedTotal; 103 );
      //map CheckDigit to font specific chars
      $C128_CheckDigit = Char( Case( vChkDigitVal = 0; 194; vChkDigitVal < 95 and vChkDigitVal > 0; vChkDigitVal +32; vChkDigitVal > 94; vChkDigitVal +100 ) );
      $DataToEncode = Substitute ( $DataToEncode; Char( 32 ); Char( 194 ) ); //replace the spaces with the 194 character, font specific
      vPrintableString = $C128_Start & $DataToEncode & $C128_CheckDigit & $C128_Stop;
      $C128_Start=""; $C128_Stop=""; $DataToEncode=""; $C128_CheckDigit=""; $WeightedTotal=""; $i="" //kill vars
      ]; vPrintableString ) //end let
  ) //end case

  ) //end let


//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> CodeSet C
; pCodeSet = "C";

  Let(
  [
  vInitOnce = Case( IsEmpty( $i );
        Let(
        [
        $C128_Start = Char( 205 );
        $C128_Stop = Char( 206 );
        $DataToEncode = Filter( pString ; "0123456789" );
        vCountOfDigitsIsOdd = Mod( Length( $DataToEncode ); 2 ) = 1;
        $DataToEncode = Case( vCountOfDigitsIsOdd; "0"; "" ) & $DataToEncode;
        $DataToPrint = "";
        $WeightValue = 0;
        $WeightedTotal = Code( $C128_Start ) -100;
        $C128_CheckDigit = "w";
        $i = -1 //...so the first used value will be 1
        ]; "" ); //end let
      "" ); //end case

  $i = $i +2;
  $WeightValue = $WeightValue +1;
  vCurrentChar = Middle( $DataToEncode; $i; 2 );
  $DataToPrint = $DataToPrint & Case( vCurrentChar < 95 and vCurrentChar > 0; Char( vCurrentChar +32 ); vCurrentChar > 94; Char( vCurrentChar +100 ); vCurrentChar = 0; Char( 194 ) );
  $WeightedTotal = $WeightedTotal + (vCurrentChar * $WeightValue)
  ];

  Case(
    $i < Length( $DataToEncode ); cfCode128( $DataToEncode; pCodeSet ); //recursion
      Let(
      [
      vChkDigitVal = Mod( $WeightedTotal; 103 );
      $C128_CheckDigit = Char( Case( vChkDigitVal < 95 and vChkDigitVal > 0; vChkDigitVal +32; vChkDigitVal > 94; vChkDigitVal +100; vChkDigitVal = 0; 194 ) );
      vPrintableString = $C128_Start & $DataToPrint & $C128_CheckDigit & $C128_Stop;
      $C128_Start=""; $C128_Stop=""; $DataToEncode=""; $DataToPrint=""; $WeightValue="";  $C128_CheckDigit=""; $WeightedTotal=""; $i=""
      ]; vPrintableString ) //end let
  ) //end case

  ) //end let

) //end case

composes the final barcode Code128 of symbology A,B or C from a given alphanumeric string.
includes the checksum of the string (modulo 103) as well as start/stop characters.
this CF is meant to be used with barcode font "IDAutomationC128..."
http://www.advancemeants.com/code128fonts/download.htm

automatic switching between variants A, B, C within a single barcode is not yet supported.

pString: string to be used as a barcode.
pCodeSet: "A" or "B" or "C" are expected.

Comments

		Kevin OShea, San Jose Apr 26, 2011
Running OS X & FM Pro 11, this function works except that spaces are not encoded properly. They turn into an invalid character (represented as Ã‚ with all the barcode fonts I've tried). As a quick solution (I was in a hurry) I just added a substitute line to substitute spaces for the Ã‚ characters and it seems to work fine.

		Eugene Gashinov, RnD Jun 15, 2012
I'm stuck on Code 128 B code over 10 chars. All my scanners won't read code without border. Can anyone help with mod to this function to make Code 128 B border in generated code?

		Eugene Gashinov, RnD Jun 30, 2012
Sry, function work fine!

		Didier, Lyon - France Dec 12, 2013
Great, smart, thanks !

		Tammo, Outlaw Dec 12, 2013
Hey Didier, thanks for your comment! Meanwhile, I'm on 4D (great, smart, faster, obsolete, grey-haired old fashioned ones have fun with it, just as me) but it's always nice to read some FRESH comments! Regards Tammo

		BDAM, USA Jan 16, 2014
If anyone is concerned with the licensing of the ID Automation fonts I can confirm that this encoding works just fine with the font available here: http://www.jtbarton.com/Barcodes/Code128.aspx Many thanks for this CF, I wasn't looking forward to hacking one together myself.

		Harald Klette, Geraldton Western Australia Jun 28, 2014
Hi, I am using the IDAutomation Code128 plugin in our filemaker database (FM11 pro) Windows 8 SP1 {4digit code} and it seemed to work all fine over the last year or two. I am doing stocktake today and the following 4 digit numbers print as a "?" 1390 1377 1370 1352 1348 1347 1346 1345 All other 4 digit numbers (from 0001 - 9999) print fine. I havent changed anything (same font same layout same character size) Label machine is DYMO labelwriter 450, but this id not the culprit as it shows already up as a "?" in Filmaker. Any idea, pointing in a directionor other help is much apprechiated. I am really confused about it. Harald

		Rafael Santana, Caracas, Venezuela Sep 15, 2014
Getting mixed results using the free Code 128 True Type font. This great function get it almost always right (as in 1977.2), failing in some 1% of times (as in 1977.3 or in 2002.37), stamping a big "Ã‚" just before the stop bars. Any ideas? Thanks!

		Rico Meier, MeiSol AG Feb 1, 2016
i have the same problem. with pcodeset "A" the number 20538 result in "Ã‚".. Cheers Rico

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfCode128 ( pString ; pCodeSet )

Comments

Support this website.

Support this website.