Levenshtein_Array_Process ( str1 ; str2 ; lenStr1 ; lenStr2 ; i ; j ; caseSensitive ; damerau ; pad )

Called by the Levenshtein function to actually calculate the distance desired.

Average rating: 4.5 (31 votes) Log in to vote

Steve Allen
Richard Carlton Consulting, Inc.
http://www.rcconsulting.com

Sample input:

Levenshtein_Array_Process ( "Steve" ; "stephen" ; 5 ; 7 ; 3 ; 2 ; True ; False ; "000" )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * Levenshtein_Array_Process ( str1 ; str2 ; lenStr1 ; lenStr2 ; i ; j ; caseSensitive ; damerau ; pad )
 * 
 * by Steve Allen; Lead Engineer; Richard Carlton Consulting, Inc.
 * P: (707) 422-4053
 * E: info@rcconsulting.com
 *
 * @version 1.0
 *
 * @description
 *
 * 	Called by the Levenshtein function (http://www.briandunning.com/cf/965)
 * 	to actually calculate the distance desired.
 *
 *	Note: best viewed in a large text space, for formatting purposes.
 * 
 * @param string str1
 *	
 *	The First String being compared.
 * 
 * @param string str2
 *	
 *	The Second String being compared.
 * 
 * @param string lenStr1
 *	
 *	Length of the First String being compared.
 *	(Also, this is the maximum coordinate of the first dimension of the array being processed.)
 * 
 * @param string lenStr2
 *	
 *	Length of the Second String being compared.
 *	(Also, this is the maximum coordinate of the second dimension of the array being processed.)
 * 
 * @param number i
 *	
 *	The current iteration in the outer loop.
 *	(The first-dimension coordinate for the cell to be cleaned by this loop iteration.)
 * 
 * @param number j
 *	
 *	The current iteration in the inner loop.
 *	(The second-dimension coordinate for the cell to be cleaned by this loop iteration.)
 *
 * @param Boolean caseSensitive
 *	
 *	True to compare the strings on a Case Sensitive basis
 *	False to compare the strings regardless of case.
 *
 *	i.e. the Case Sensitive distance between "Steve" and "steve" is 1, whereas
 *	the Case Insenseitive distance between "Steve" and "steve" is 0.
 * 
 * @param Boolean damerau
 *	
 *	True to return Damerau-Levenshtein distance.
 *	False to return Levenshtein distance.
 *
 * @param string pad
 *
 *	Padding string.  See note 1 in Levenshtein function comments.
 *	(Should be all 0's, but this is not validated.)
 *
 */

Case ( i <= lenStr1 ;
	Case ( j <= lenStr2 ;
		Let ([
			lenPad	= Length ( pad )
		;	cost	= not Exact ( Middle ( str1 ; i ; 1 ) ; Middle ( str2 ; j ; 1 ) )
		;	cell	= GetAsNumber ( Right ( pad & i	; lenPad )	& Right ( pad & j 	; lenPad ) )
		;	delCell	= GetAsNumber ( Right ( pad & i - 1	; lenPad )	& Right ( pad & j 	; lenPad ) )
		;	insCell	= GetAsNumber ( Right ( pad & i	; lenPad )	& Right ( pad & j - 1	; lenPad ) )
		;	subCell	= GetAsNumber ( Right ( pad & i - 1	; lenPad )	& Right ( pad & j - 1	; lenPad ) )
		;	trnCell	= GetAsNumber ( Right ( pad & i - 2	; lenPad )	& Right ( pad & j - 2	; lenPad ) )
		;	$$_ld_array[cell] =
				Min (
					$$_ld_array[delCell] + 1
				;	$$_ld_array[insCell] + 1
				;	$$_ld_array[subCell] + cost
				)
		;	$$_ld_array[cell] = 
				Case ( 
					damerau ;
						Case (
							i > 1
						and	j > 1
						and	Exact ( Middle ( str1 ; i ; 1 ) ; Middle ( str2 ; j - 1 ; 1 ) )
						and	Exact ( Middle ( str1 ; i - 1 ; 1 ) ; Middle ( str2 ; j ; 1 ) )
						;	Min(
								$$_ld_array[cell]
							;	$$_ld_array[trnCell] + cost
							)
						;	$$_ld_array[cell]
						)
				;	$$_ld_array[cell]
				)
		];
			Levenshtein_Array_Process ( str1 ; str2 ; lenStr1 ; lenStr2 ; i ; j + 1 ; caseSensitive ; damerau ; pad )
		)
	;	Levenshtein_Array_Process ( str1 ; str2 ; lenStr1 ; lenStr2 ; i + 1 ; 1 ; caseSensitive ; damerau ; pad )
	)
;	"Processed"
)

Called by the Levenshtein function to actually calculate the distance desired.

Note: best viewed in a large text space, for formatting purposes.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Levenshtein_Array_Process ( str1 ; str2 ; lenStr1 ; lenStr2 ; i ; j ; caseSensitive ; damerau ; pad )

Comments

Support this website.

Support this website.