convert_gps_gausskrueger2wgs84 ( coordinate ; error )

Converts an Gauß-Krüger-coordinate (as used by O2) to an comma-seperated WGS84-coordinate

Average rating: 4.2 (38 votes) Log in to vote

Rewolfer - Show more from this author
http://rewolfer.de

Sample input:

convert_gps_gausskrueger2wgs84(379895583291; "not found")

Sample output:

52.54708403520126,13.4068830293585

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let (
    [
    // we need to make sure we have correct o2-gauß-krüger-data
    error_check = Case (Length(Filter(coordinate; "0123456789")) = 12; 0; 1);
    co_right = GetAsNumber(Left(coordinate; 6) & "0");
    co_high = GetAsNumber(Right(coordinate; 6) & "0");
    
    Pi = 3,14159265;
    e2 = ,0067192188;
    c = 6398786,849;
    rho = 180 / Pi;
    bII = (co_high / 10000855,7646) * (co_high / 10000855,7646);
    bf = 325632,08677 * (co_high / 10000855,7646) * ((((((,00000562025 * bII + ,00022976983) * bII - ,00113566119) * bII + ,00424914906) * bII - ,00831729565) * bII + 1));
    bf = bf / (3600 * rho);
    co = Cos ( bf );
    g2 = e2 * (co * co);
    g1 = c / Sqrt (1 + g2);
    t = Tan (bf);
    fa = (co_right  - Floor( co_right / 1000000) * 1000000 - 500000) / g1;
    dl = fa - fa * fa * fa * (1 + 2 * t * t + g2) / 6 + fa * fa * fa * fa * fa * (1 + 28 * t * t + 24 * t * t * t * t) / 120;

    //—————————- decimal latitude (right) and longitude (high)
    temp_right = ((bf - fa * fa * t * (1 + g2) / 2 + fa * fa * fa * fa * t * (5 + 3 * t * t + 6 * g2 - 6 * g2 * t * t) / 24) * rho);
    temp_high = dl * rho / co + Floor(co_right / 1000000) * 3;

    //—————————- from here on data will be transformed to wgs84
    temp_right = (temp_right  / 180) * Pi;
    temp_high = (temp_high / 180) * Pi;

    aBessel = 6377397,155;
    eeBessel = ,0066743722296294277832;
    ScaleFactor = ,00000982;
    RotXRad = -7,16069806998785e-6;
    RotYRad = 3,56822869296619e-7;
    RotZRad = 7,06858347057704e-6;
    ShiftXMeters = 591,28;
    ShiftYMeters = 81,35;
    ShiftZMeters = 396,39;

    n = eeBessel * Sin(temp_right) * Sin(temp_right);
    n = 1 - n;
    n = Sqrt(n);
    n = aBessel / n;
    CartesianXMeters = n * Cos(temp_right) * Cos(temp_high);
    CartesianYMeters = n * Cos(temp_right) * Sin(temp_high);
    CartesianZMeters = n * (1 - eeBessel) * Sin(temp_right);
    CartOutputXMeters = (1 + ScaleFactor) * CartesianXMeters + RotZRad * CartesianYMeters - RotYRad * CartesianZMeters + ShiftXMeters;
    CartOutputYMeters = -RotZRad * CartesianXMeters + (1 + ScaleFactor) * CartesianYMeters + RotXRad * CartesianZMeters + ShiftYMeters;
    CartOutputZMeters = RotYRad * CartesianXMeters - RotXRad * CartesianYMeters + (1 + ScaleFactor) * CartesianZMeters + ShiftZMeters;
	
    temp_high = Atan((CartOutputYMeters / CartOutputXMeters));
    Latitude = (CartOutputXMeters * CartOutputXMeters) + (CartOutputYMeters * CartOutputYMeters);
    Latitude = Sqrt(Latitude);
    Latitude = CartOutputZMeters / Latitude;
    Latitude =  Atan(Latitude);

    // recursive transition of latitude needs to be checked in advance to avoid endless loops
    final_latitude = Case( error_check = 0; convert_gps_gausskrueger2wgs84_sub(Latitude; CartOutputXMeters; CartOutputYMeters; CartOutputZMeters));
    final_latitude = Round((final_latitude / Pi) * 180; 8);
    final_longitude = Round((temp_high / Pi) * 180; 8);

    result = Substitute(GetAsText(final_latitude); ","; ".") & "," & Substitute(GetAsText(final_longitude); ","; ".")
    
    ];

    Case( error_check = 0; result; error)
)

Converts a Gauß-Krüger-coordinate (as used by mobile carrier O2Germany) to a comma-seperated WGS84-coordinate (as used by GoogleMaps).
Several transformations. Gives customizable error feedback.
Needs helper function convert_gps_gausskrueger2wgs84_sub (listed here as well).

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

convert_gps_gausskrueger2wgs84 ( coordinate ; error )

Comments

Support this website.

Support this website.