IndianNotation ( number )

Returns a number formatted according to the Indian notation

Average rating: 4.7 (19 votes) Log in to vote

Daniele Raybaudi - Show more from this author
ACI
http://www.aci.it

Sample input:

IndianNotation ( 234578 )
IndianNotation ( 1000000000000 )
IndianNotation ( 1234567890127.413 )

Sample output:

2,34,578
10,00,00,00,00,000
12,34,56,78,90,127.413

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
IndianNotation ( number )

This recursive custom function generates a number formatted according to the Indian notation that can be treated like any other number of the DB, including sorting.
It has no practical limitations because the mask is dynamically generated based on the length of the number.
It evaluates both positive and negative numbers, integers or decimal.
The decimal part is separated from the integer part by a dot, if we are in America, by a comma, if we are in Italy. ;-)
The calculated field must return a result of type number and must be formatted in Layout Mode "As entered", not "General".

Daniele Raybaudi

2015/06/26

*/

Let ([
is negative = number < 0 ;
decimal part = If ( Mod ( Abs ( number ) ; 1 ) ; Mod ( Abs ( number ) ; 1 ) ) ;
integer part = If ( decimal part ; Left ( number ; Position ( number; Left ( 1/2 ; 1 ) ; 1 ; 1 ) - 1 )  ; number ) ;
separator = If ( Left ( 1/2 ; 1 ) = "." ; "," ; "." ) ;
mask = Substitute ( 10 ^ ( Div ( Max ( Floor ( Log ( Abs ( integer part ) ) ) + 1 ; 0 ) ; 2 ) ) - 1  ; 9 ; "≠≠" & separator ) & "≠≠≠" ;
$IndianNotationCount = $IndianNotationCount + 1 ;
mask char = Middle ( mask ; Length ( mask ) + 1 - $IndianNotationCount ; 1 ) ;
already entered separators = PatternCount ( Right ( mask ; $IndianNotationCount  ) ; separator ) ;
number char = Middle ( integer part ; Length ( integer part ) + 1 - $IndianNotationCount + already entered separators ; 1 ) ;
char = If ( not IsEmpty ( Filter ( "≠" ; mask char ) ) ; number char ; mask char ) ;
stop = Length ( integer part ) + already entered separators - is negative
];
If ( $IndianNotationCount < stop ; IndianNotation ( integer part ) ; Let ( $IndianNotationCount = "" ; If ( is negative ; "-" ) ) )  & char & decimal part
)

This recursive custom function generates a number formatted according to the Indian notation that can be treated like any other number of the DB, including sorting.

It has no practical limitations because the mask is dynamically generated based on the length of the number.

It evaluates both positive and negative numbers, integers or decimal.

The decimal part is separated from the integer part by a dot, if we are in America, by a comma, if we are in Italy. ;-)

The calculated field must return a result of type number and must be formatted in Layout Mode "As entered", not "General".

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

IndianNotation ( number )

Comments

Support this website.

Support this website.