ParseName ( name )

Parses a name into a JSON object

Average rating: 5.0 (1 vote) Log in to vote

Richard Dyce - Show more from this author
Dyce & Sons Ltd.
http://dyce.com

Sample input:

ParseName ( "Dr Sara-Louise M Pleydell-Smith Msc PhD" )

Sample output:

{"forename":"Sara-Louise","initials":"M","suffix":"Msc PhD","surname":"Pleydell-Smith","title":"Dr"}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// ParseName ( name )

Let(
	[
		parts = Substitute ( name ; [ " " ; ¶ ]; [ "." ; ¶ ] ; [ "¶¶" ; ¶ ] ) ;

		titles = "Mr¶Miss¶Mrs¶Ms¶Dr¶Sr¶Sra¶Srta¶Lic¶Sir¶Rev¶Prof¶Professor¶Lady¶Lord¶Dame¶Ing" ;
		titleCount = ValueCount ( FilterValues ( parts ; titles ) ) ;
		title = Trim ( Substitute ( LeftValues ( parts ; ValueCount ( FilterValues ( parts ; titles ) ) ) ; ¶ ; " " ) ) ;

		genitives = "al¶de¶del¶di¶don¶la¶le¶von¶Von¶Van¶van" ;
		genitiveCount = ValueCount ( FilterValues ( parts ; genitives ) ) ;

		suffices = "Jr¶Sr¶PhD¶MD¶JD¶DDS¶MBA¶CPA¶CEO¶CFO¶CTO¶CTO¶COO¶BA¶MSc¶BSc¶MEng¶BEng" ;
		suffixCount = ValueCount ( FilterValues ( parts ; suffices ) ) ;

		nameParts = MiddleValues ( parts ; titleCount + 1 ; ValueCount ( parts ) - titleCount - suffixCount ) ;
		partCount = ValueCount ( nameParts ) ;

		// How many words in the surname? take account of "de la Pleydell-Smith"
		surnameCount = 1 + genitiveCount ;
		middleCount = partCount - surnameCount - 1 ;

		suffix = Trim ( Substitute ( RightValues ( parts ; suffixCount ) ; ¶ ; " " ) )  ;
		forename = Trim ( GetValue ( nameParts ; 1 ) ) ;
		initials = Trim ( Substitute ( MiddleValues( nameParts ; 2 ; middleCount ) ; ¶ ; " " ) ) ;
		surname = Trim ( Substitute ( RightValues ( nameParts ; surnameCount ) ; ¶ ; " " ) )
	] ;

	JSONSetElement ( 
		"{}" ;
		[ "title" ; title ; JSONString ] ;
		[ "forename" ; If (forename ≠ surname ; forename ; If ( IsEmpty ( title ) ; forename; "" ) ) ; JSONString ] ;
		[ "initials" ; initials ; JSONString ] ;
		[ "surname" ; If( forename ≠ surname ; surname ;  If( IsEmpty ( title ) ; "" ; surname ) ) ; JSONString ] ;
		[ "suffix" ; suffix ; JSONString ]

	)
)

I use this to simplify data entry - let the user enter a full name, and then pull it into sub fields using FileMaker's JSON functions.

I *think* I've covered most standard cases - but the genitives list, titles, and suffices can easily be expanded.

Comments

		Joshua Willing, Willing Apps Apr 21, 2019
Parsing names is dicey business. Good luck!

		Joshua Willing, Willing Apps Apr 21, 2019
you might wanna consider roman numerals in suffixes e.g. William Henry Gates III

		Richard Dyce, Dyce & Sons Ltd. Apr 22, 2019
I might ;-) Adding them would be easy - simply append them to the suffix list: suffices = "JrÂ¶SrÂ¶PhDÂ¶MDÂ¶JDÂ¶DDSÂ¶MBAÂ¶CPAÂ¶CEOÂ¶CFOÂ¶CTOÂ¶CTOÂ¶COOÂ¶BAÂ¶MScÂ¶BScÂ¶MEngÂ¶BEngÂ¶IÂ¶IIÂ¶IIIÂ¶IVÂ¶VÂ¶VI" ; Strangely, it's not that much of a big deal here in Europe, at least for non-Royalty ;-)

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ParseName ( name )

Comments

Support this website.

Support this website.