cfCode128Mod ( pString ; pCodeSet )

Modified cfCode128() for a different Code128 font. Also reduce potential script errors.

Be the first to rate this function Log in to vote

Philip Wang - Show more from this author
106th Street Wheel and Tire
http://www.106sttire.com

Sample input:

4T1BK36B25U059897; "A"
1HGCR3F83GA022209; "A"
123456789; "C"

Sample output:

Ð4T1BK36B25U059897iÓ
Ð1HGCR3F83GA0222095Ó
Ò!7Mcy iÓ

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
cfCode128Mod ( pString; pCodeSet )
This function is modified from Tammo and Felix's cfCode128() function to adapt it for a different Code128 font.
Also now $i becomes $i_C128 to reduce the chance of a script error.
Tested with my Windows 7 machines with 128 Code A only. Code C should work, but if it doesn't, please comment below.
I kept all their comments and added mine modifications.

---Original Comment---
---use with FM version >= 10---
composes the final barcode Code128 of symbology A,B or C from a given alphanumeric string.
includes the checksum of the string (modulo 103) as well as start/stop characters.
this CF is meant to be used with barcode font "IDAutomationC128..."
http://www.advancemeants.com/code128fonts/download.htm

automatic switching between variants A,B,C within a single barcode is not yet supported.

pString: string to be used as a barcode.
pCodeSet: "A" or "B" or "C" are expected.
local var $i_C128 stores the actual count of loops.
be careful, $i_C128 var should not be used in a script running at the same time.
all vars (although locally stored) should be destroyed when the process is done.

author: tammo fornalik / felix hausberner, dbyte solutions, 01.06.2008
changes: 10.01.2009, Code() and Char() are now native functions in FM10, replaced references to CFs which did that job.
type: recursive
dependencies: none
call like: cfCode128( "SBM16672_2008_08_25"; "B" )
*/

//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> String is empty -> no output
Case( IsEmpty( pString ); ""

//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> CodeSet A, B
; pCodeSet = "A" or pCodeSet = "B";

   Let([
     vInitOnce=If( IsEmpty( $i_C128 );
		   //the following inits are only processed during initial call
		   Let([
			  $C128_Start = Char( Case( pCodeSet = "A"; 208; pCodeSet = "B"; 209; 210 ) ); //defined by C128 specs, changed by Philip for new font
			  $C128_Stop = Char( 211 ); //defined by C128 specs, changed by Philip
			  $DataToEncode = Trim( pString );
			  $WeightedTotal = Code( $C128_Start ) -105; //font specific, changed by Philip
			  $C128_CheckDigit = "w"; //font specific, on internal error
			  $i_C128 = 0
		   ]; "" ); //end let
		 "" ); //end if

	  $i_C128 = $i_C128 +1;
	  //get the value of each character. calculate the WeightedTotal for modulo 103 checksum.

	  vCurrentChar = Code( Middle( $DataToEncode; $i_C128; 1 ) );
	  // Below changed by Philip, no way the current character is above 127. This function doesn't do unicode or special characters.
	  vCurrentVal = vCurrentChar - 32;   
	  $WeightedTotal = $WeightedTotal + vCurrentVal*$i_C128
      ];
	  // result is:
	  Case(
		 $i_C128 + 1< Length( $DataToEncode ); cfCode128Mod( $DataToEncode; pCodeSet ); //recursion
		 // Recursion done.
		 Let([
			//divide the WeightedTotal by 103 and get the remainder, this is the CheckDigitValue
			vChkDigitVal = Mod( $WeightedTotal; 103 );
			//map CheckDigit to font specific chars, changed by Philip, Special mapping change to 105 instead of 100.
			$C128_CheckDigit = Char( Case( vChkDigitVal < 95; vChkDigitVal +32; vChkDigitVal +105 ) );
			vPrintOut= $C128_Start & $DataToEncode & $C128_CheckDigit & $C128_Stop;
			// clear all the variables
			$C128_Start=""; $C128_Stop=""; $DataToEncode=""; $C128_CheckDigit=""; $WeightedTotal=""; $i_C128=""
		   ]; // (Philip) Below is the printout result.
		   vPrintOut) //end let
	  ) //end case

  ) //end let


//>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> CodeSet C
; pCodeSet = "C";
   Let([
	  vInitOnce =
	  If( IsEmpty( $i_C128 );
		 Let([
			$C128_Start = Char( 210 );
			$C128_Stop = Char( 211 );
			$DataToEncode = Filter( pString ; "0123456789" );
			vCountOfDigitsIsOdd = Mod( Length( $DataToEncode ); 2 );
			$DataToEncode = If( vCountOfDigitsIsOdd=1; "0"; "" ) & $DataToEncode;
			$DataToPrint = "";
			$WeightValue = 0;
			$WeightedTotal = 105;
			$C128_CheckDigit = "w";
			$C128_PrintOut = "";
			$i_C128 = -1 //...so the first used value will be 1
		 ]; "" ); //end let
	  "" ); //end if

	 $i_C128 = $i_C128 +2;
	 $WeightValue = $WeightValue +1;
	 vCurrentChar = GetAsNumber ( Middle( $DataToEncode; $i_C128; 2 )) ;
	 // Below changed by Philip, no special handling of space to Char(194), add 105 instead of 100 for value >94.
                $DataToPrint = $DataToPrint & Case( vCurrentChar < 95; Char( vCurrentChar +32 ); Char( vCurrentChar +105) ); 
	 $WeightedTotal = $WeightedTotal + (vCurrentChar * $WeightValue)
	 ];
	  // Result is:
	  Case(
	   $i_C128 + 2< Length( $DataToEncode ); cfCode128Mod( $DataToEncode; pCodeSet ); //recursion
	   // Recursion done.
		 Let([
			 vChkDigitVal = Mod( $WeightedTotal; 103 );
			 // Belong changed by Philip, no special handling of space, add 105 to value>94 instead of 100
			 $C128_CheckDigit = Char( Case( vChkDigitVal < 95; vChkDigitVal +32; vChkDigitVal +105) );
			 vPrintOut = $C128_Start & $DataToPrint & $C128_CheckDigit & $C128_Stop;
			 // clear all the varaibles
			 $C128_Start=""; $C128_Stop=""; $DataToEncode=""; $DataToPrint=""; $WeightValue="";  $C128_CheckDigit=""; $WeightedTotal=""; $i_C128=""
		 ]; vPrintOut ) //end let
	  ) //end case

   ) //end let

) //end case

Love the excellent cfCode128 function from Tammo and Felix, but unfortunately I can only get hold of an incompatible code128 font. So in order to make this font work I changed some character codes in this function, also fix a little bit here and there, but main kudos should go to Tammo and Felix.
( Updated 06/03/2021: Fix the trailing 0 problem for code set "C". )

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfCode128Mod ( pString ; pCodeSet )

Comments

Support this website.

Support this website.