SwapValues ( list ; value1 ; value2 )

Swaps two items in a valuelist

Average rating: 4.3 (28 votes) Log in to vote

Theo Ros - Show more from this author

Sample input:

SwapValues ( "John¶Paul¶George¶Ringo" ; 1 ; 3 )

Sample output:

George¶Paul¶John¶Ringo

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ----------------------------------------------------------
Swaps two items in a valuelist

In: list - the list of Return delimited values
      value1 - the number of the first value to swap
      value2 - the number of the second value to swap

If the given value numbers are outside the total range
of the list, no action is taken and the list is returned
unchanged. If value1 and value2 are equal numbers, 
again nothing is done to the original list.
When the function does swap values, a list is returned
without leading or trailing returns.

Return type: Text
Syntax: SwapValues ( list ; value1 ; value2 )

SwapValues ( "John¶Paul¶George¶Ringo" ; 1 ; 3 ) 
returns "George¶Paul¶John¶Ringo"

Note: for best results, trim empty returns from the list
before calling this function by using LeftWords ( list ; 999999999 )

Theo Ros
----------------------------------------------------------*/

Let ( totalvalues = ValueCount ( list ) ;
  // bail out if values ar out of range or the list is empty
  If ( totalvalues ;
    Case ( value1 = value2 ; list ;
               value1 < 1 or value1 > totalvalues ; list ;
               value2 < 1 or value2 > totalvalues ; list ;
      // determine the left and rightmost values
      Let ( [ vLeft = If ( value1 < value2 ; value1 ; value2 ) ;
                 vRight = If ( value2 > value1 ; value2 ; value1 ) ] ;
                 // rebuild the list and delete any leading or trailing returns
                LeftWords ( LeftValues ( list ; vLeft -1 ) & 
                  MiddleValues ( list ; vRight ; 1 ) &
                  MiddleValues ( list ; vLeft + 1 ; vRight - vLeft - 1 ) &
                  MiddleValues ( list ; vLeft ; 1 ) & 
                  RightValues ( list ; totalvalues - vRight ) ; 999999999 ) 
      )
    )
  )
)

Swaps two items in a valuelist

In: list - the list of Return delimited values
value1 - the number of the first value to swap
value2 - the number of the second value to swap

If the given value numbers are outside the total range of the list, no action is taken and the list is returned unchanged. If value1 and value2 are equal numbers, again nothing is done to the original list. When the function does swap values, a list is returned without leading or trailing returns.

Return type: Text
Syntax: SwapValues ( list ; value1 ; value2 )

SwapValues ( "John¶Paul¶George¶Ringo" ; 1 ; 3 )
returns "George¶Paul¶John¶Ringo"

Note: for best results, trim empty returns from the list before calling this function by using LeftWords ( list ; 999999999 )

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

SwapValues ( list ; value1 ; value2 )

Comments

Support this website.

Support this website.