HolidayListByYear ( yearNumber )

Creates a list of holiday names and dates for a given year.

Average rating: 4.5 (32 votes) Log in to vote

Jonathan Mickelson - Show more from this author

Sample input:

HolidayListByYear ( 2004 )

Sample output:

"New Year's Day = 1/1/2004¶
Martin Luther King Day = 1/19/2004¶
..."

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let(
 [ 
Y = yearNumber ; 
// ------------- BEGIN EASTER CALCULATION ---------------
// --------- Begin OUDIN's Easter (Western) Algorithm ----------
century = Div ( Y ; 100 ) ; 
G = Mod ( Y ; 19 ) ; 
K = Div ( century - 17 ; 25 ) ; 
I = Mod ( ( century - Div ( century ; 4 ) - Div ( century - K ; 3 ) + 19 * G + 15 ) ; 30 ) ; 
Ia = I - Div ( I ; 28 ) * ( 1 - Div ( I ; 28 ) * Div ( 29 ; I + 1 ) * Div ( 21 - G ; 11 ) ) ; 
J = Mod ( Y + Div ( Y ; 4 ) + Ia + 2 - century + Div ( century ; 4 ) ; 7 ) ; 
L = Ia - J ; 
EasterM = 3 + Div ( L + 40 ; 44 ) ; 
EasterD = L + 28 - 31* Div ( EasterM ; 4) ; 
// --------- Begin OUDIN's Easter (Western) Algorithm ----------

/*
THIS OPTIONAL EASTER FUNCTION IS PROVIDED FOR AN ALTERNATIVE
BUT THEY BOTH RESULT IN THE SAME RESULTS!! 
// --------- Begin BUTCHER's Easter (Western) Algorithm ----------
a = Mod ( Y ; 19 ) ; 
b = Div ( Y ; 100 ) ; 
c = Mod ( Y ; 100 ) ; 
d = Div ( b; 4 ) ; 
e = Mod ( b ; 4 ) ; 
f = Div ( b + 8 ; 25 ) ; 
g = Div ( b - f + 1 ; 3 ) ; 
h = Mod ( 19 * a + b - d - g + 15 ; 30 ); 
i = Div ( c ; 4 ) ; 
k = Mod ( c ; 4 ) ; 
l = Mod ( 32 + 2 * e + 2 * i - h - k ; 7 ); 
m = Div ( a + 11 * h + 22 * l ; 451 )  ; 
EasterM = Div ( h + l - 7 * m + 114 ; 31 ) ;         // 3=March, 4=April 
EasterD = Mod ( h + l - 7 * m + 114 ; 31 ) +1 ;  // day in Easter Month 
// --------- Begin Butcher's Easter (Western) Algorithm ----------
*/

// EASTER RESULT
easterDate = Date ( EasterM ; EasterD ; Y ) ; 
// ------------- END EASTER CALCULATIONS ---------------

// ---------------DEFINE HOLIDAYS LIST -------------------
// DateByDayOccur( yearNum; monthNum; dayOfWeekNum; dayOccurance)
//   - dayOfWeekNum:  1=Sun,2=Mon,3=Tue,4=Wed,5=Thu,6=Fri,7=Sat 
//   - dayOccurance:   1=1st,2=2nd,3=3rd,4=4th,5=5th,""=Last
// Builds a return delimited list of Dates and Titles separated by a "=" 

holidayList = 
// NEW YEARS - Jan 1
      "New Year's Day = " & 
      Date ( 1 ; 1 ; Y ) & "¶" 
& 
// NEW YEARS (OBSERVED) - If a weekend, choose weekday
Case ( 
  DayOfWeek ( Date ( 1 ; 1 ; Y ) ) = 1 ; 
     "New Year's Day (Observed) = " & 
      Date ( 1 ; 1 ; Y ) + 1 & "¶" 
) // END Case
& 
// MARTIN LUTHER KING - *Third Monday in January*
      "Martin Luther King Day = " &
       DateByDayOccur ( Y ; 1 ; 2 ; 3 ) & "¶" 
&
// VALENTINE'S DAY - Feb 14
     "Valentine's Day = "  & 
     Date ( 2 ; 14 ; Y )& "¶" 
& 
// PRESIDENT'S DAY - *Third Monday in February*
     "President's Day = " & 
     DateByDayOccur ( Y ; 2 ; 2 ; 3 ) & "¶" 
& 
// ST. PATRICK'S DAY - Mar 17
     "St. Patrick's Day = " & 
     Date ( 3 ; 17 ; Y ) & "¶" 
& 
// EASTER - See Easter Calc Above 
     "Easter = "& 
      easterDate & "¶" 
& 
// CINCO DE MAYO - May 5 
     "Cinco De Mayo = " & 
     Date ( 5 ; 5 ; Y ) & "¶" 
& 
// MEMORIAL DAY - *Last Monday in May* 
     "Memorial Day (Observed) = " & 
      DateByDayOccur ( Y ; 5 ; 2 ; "" ) & "¶" 
& 
// INDEPENDANCE DAY - July 4 
     "Independence Day = " & 
      Date ( 7 ; 4 ; Y )& "¶" 
& 
// INDEPENDENCE DAY - If a weekend, Choose weekday 
Case ( 
  DayOfWeek ( Date ( 7 ; 4 ; Y ) ) = 7 ; 
     "Independence Day (Observed) = " & 
      Date ( 7 ; 4 ; Y ) - 1 & "¶" ; 

  DayOfWeek ( Date ( 7 ; 4 ; Y ) ) = 1 ; 
     "Independence Day (Observed) = " & 
     Date ( 7 ; 4 ; Y ) + 1 & "¶" 
)  // END Case
&
// LABOR DAY- *First Monday in September* 
     "Labor Day = " & 
      DateByDayOccur ( Y ; 9 ; 2 ; 1 ) & "¶" 
& 
// COLUMBUS DAY - *Second Monday in October* 
     "Columbus Day (Observed) = " & 
      DateByDayOccur ( Y ; 10 ; 2 ; 2 ) & "¶" 
& 
// HALLOWEEN - Oct 31 
     "Halloween = " & 
      Date ( 10 ; 31 ; Y ) & "¶" 
& 
// THANKSGIVING DAY - *Fourth Thursday in November* 
     "Thanksgiving Day = " & 
      DateByDayOccur ( Y ; 11 ; 5 ; 4 ) & "¶" 
& 
// CHRISTMAS DAY - Dec 25 
     "Christmas Day = " & 
     Date ( 12 ; 25; Y ) & "¶" 
& 
// NEW YEARS NEXT YEAR on weekend falls back a year!
Case ( 
  DayOfWeek ( Date ( 1 ; 1 ; Y + 1 ) ) = 7 ; 
    "New Year's Day " & Y + 1 & " (Observed) = " & 
     Date ( 1 ; 1 ; Y + 1 ) - 1 & "¶" 
)   // END Case
// END holidayList
 ] ;   //  -------- END VARIABLE DEFINITIONS ----------------//
Case (                                                                                                                             
       // ERROR: Return "Null" Result if no year supplied
           not IsEmpty ( yearNumber ) ; 

       // SUCCESS! Display Result
            holidayList
         )  // END CASE
)  // END LET

This function returns a list of US (can be modified for other countries) Holiday Names for the supplied 4 digit Year, followwed by a "=" and its actual date that year. The list of Holidays can be found/modified/expanded in the Variable declarations within the calculation.

NOTE: This function requires the use of another custom function called: "DateByDayOccur" which performs date calculations for holidays which occur on certain occurances of a day within a month, as in the example of Thanksgiving which falls on the "Fourth Thursday of November".

Output: Text value List of Holiday Names followed by "=" and the date

HolidayListByYear ( 2004 ) = "New Year's Day = 1/1/2004¶
Martin Luther King Day = 1/19/2004¶
..."

Parameters: yearNumber - any valid 4 digit Year

Special thanks: To Dan Kaplan, of abledesign.com for distilling
many holiday/calendaring sources on the net.

Comments

		Sterling Ledet, Atlanta, GA Aug 14, 2016
The Thanksgiving Day subroutine is inconsistent with the other ones and is missing a space. Should be "Thanksgiving Day = " & DateByDayOccur ( Y ;Â 11 ;Â 5 ;Â 4 ) & "Â¶"

		Jonathan, Los Angeles Mar 6, 2017
Thanks for the note Sterling, this has now been fixed in the source on this site.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HolidayListByYear ( yearNumber )

Comments

Support this website.

Support this website.