Verhoeff ( numericString ; index ; checkSum )

Average rating: 3.7 (58 votes) Log in to vote

Michael Horak - Show more from this author
*COMMENT Visual Realisation

Sample input:

Verhoeff ( "1428570" ; 0 ; 0 )

Middle ( "0432156789" ; Verhoeff ( "142857" & "0" ; 0 ; 0 ) + 1 ; 1 )

Sample output:

0

0

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
Verhoeff function

Author
*COMMENT Visual Realisation

Format
Verhoeff ( numericString ; index ; checkSum )

Parameters
numericString - a string of numeric characters (digits) or field containing numeric characters
index - indicates the digit position of the current iteration - needs to be initialized to zero (0) when calling the function
checkSum - indicates the check digit of the current iteration - needs to be initialized to zero (0) when calling the function

Data type returned
number

Description
Returns the Verhoeff dihedral check digit of numericString. Use this function to verify a numeric string protected by Verhoeff check digit, or to generate the correct Verhoeff check digit for a given numeric string.

December 20, 2006
*/


Let ( [ 
n = Right ( numericString ; 1 ) ;

p = Let ( [
array = "01234567891576283094580379614289160435279453126870428657390127938064157046913258" ; 
start = 10 * Mod ( index ; 8 ) + n + 1
] ;
Middle ( array ; start ; 1 ) 
) ;

d = Let ( [
array = "0123456789123406789523401789563401289567401239567859876043216598710432765982104387659321049876543210" ; 
start = 10 * checkSum + p + 1
] ;
Middle ( array ; start ; 1 ) 
) ; 

len = Length ( numericString ) ;
nextString = Left ( numericString ; len - 1 ) 
] ;
Case ( len > 1 ; Verhoeff ( nextString ; index + 1 ; d ) ; d )
)

Returns the Verhoeff dihedral check digit of numericString. Use this function to verify a numeric string protected by a Verhoeff check digit, or to generate the correct Verhoeff check digit for a given numeric string.

For more information about the Verhoeff algorithm, see:
http://en.wikipedia.org/wiki/Verhoeff_algorithm

EXAMPLES OF CALLING THE FUNCTION

1. To extract the check digit from a string in Input field:

Verhoeff ( Input ; 0 ; 0 )

A result of zero (0) indicates a valid entry; any other result indicates a data entry error.

2. To validate an entry in Input field:

not Verhoeff ( Input ; 0 ; 0 )

3. To generate a check digit for a string in Input field:

Middle ( "0432156789" ; Verhoeff ( Input & "0" ; 0 ; 0 ) + 1 ; 1 )

4. To append a check digit to a string in Input field:

Input & Middle ( "0432156789" ; Verhoeff ( Input & "0" ; 0 ; 0 ) + 1 ; 1 )

Comments

		Rodolfo Vargas, Santa Cruz - Bolivia Nov 25, 2012
Desarrollo en File Maker 9,11,12 y pondre a prueba esta funcioin , paRA GENERAR UN CODIGO DE CONTROL....en facturas para impuestos internos......

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Verhoeff ( numericString ; index ; checkSum )

Comments

Support this website.

Support this website.