IndexList ( size )

Speedily (and with limited recursion) return a list of up to one million integers from 0 to (size-1).

Average rating: 4.4 (32 votes) Log in to vote

Debi Fuchs - Show more from this author
Aptworks Consulting
http://www.aptworks.com

Sample input:

IndexList ( 100 )

Sample output:

"01¶02¶03¶...¶99"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
CUSTOM FUNCTION: IndexList ( size )
© 2008 Debi Fuchs of Aptworks Consulting, debi@aptworks.com

Speedily (and with limited recursion) return an "index list" of integers from 0 to (size-1). This is useful mostly as a helper to various other functions.

NOTE: This implementation uses no recursion. (See IndexList_PartlyRecursive for a recursive version. It uses just a little more stack space, but is slightly faster than this one.)

LAST MODIFIED: 13-AUG-2008 by Debi Fuchs of Aptworks Consulting
*/


Case(

  // Simpulate an out-of-range error if the size parameter is huge. 
  // (NOTE: This function can be extended to deal with higher
  // values if useful/practical.)
  
  size > 1000000; Evaluate( "Factorial( -1 )" );
  
  // Test the size parameter for some "quick exit" conditions.

  size < 1; "";

  size < 2;  "0";
  
  // Build a list by repeatedly (once for each power of
  // ten) stringing together a set of 10 substitutions (for
  // digits 0 through 9) applied to the prior iteration result.

  Let(
    [
      // Force size to an integer if necessary.
      size=Int(size); 
    
      // Create a string representing 10 substitutions (one
      // per digit 0 through 9).

      iteration_string =
         "new_list_mod= \"\¶\" & new_list;" &
         "new_list=\"0\" & " &
              "Substitute(new_list;\"\¶\";\"\¶0\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶1\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶2\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶3\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶4\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶5\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶6\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶7\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶8\") & " &
              "Substitute(new_list_mod;\"\¶\";\"\¶9\")";
       
      // Create a string to apply the above once for each power of 10.

      power_of_10 = Ceiling( Log( size ) );
      iteration_strings_appended = 
        Substitute(
          Left( ";0;0;0;0;0;0;0;0"; 2 * ( power_of_10 - 1 ) );
          0;
          iteration_string
        )
    ];
    
    // Starting with an intial value for size=10, evaluate
    // the string constructed above, returning only the
    // relevant subset of values from the result.
    
    Let(
      [
        initial_value = "0¶1¶2¶3¶4¶5¶6¶7¶8¶9";
        evaluation_string = 
            "Let(" &
                 "[" &
                   "new_list=" & Quote( initial_value ) & 
                   iteration_strings_appended & " & \"\"" & 
                 "];" &
                 "new_list" & 
             ")";
        substring_length = size * ( power_of_10 + 1 ) - 1
      ];
      Middle( Evaluate( evaluation_string ); 1; substring_length )
    )
  )
)

/*
CUSTOM FUNCTION: IndexList ( size )
© 2008 Debi Fuchs of Aptworks Consulting, debi@aptworks.com

Speedily (and with limited recursion) return an "index list" of integers from 0 to (size-1). This is useful mostly as a helper to various other functions.

NOTE: This implementation uses no recursion. (See IndexList_PartlyRecursive for a recursive version. It uses just a little more stack space, but is slightly faster than this one.)

LAST MODIFIED: 13-AUG-2008 by Debi Fuchs of Aptworks Consulting

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

IndexList ( size )

Comments

Support this website.

Support this website.